1 files changed, 52 insertions, 0 deletions
diff --git a/sys-cluster/libqb/libqb-0.14.4.ebuild b/sys-cluster/libqb/libqb-0.14.4.ebuild
new file mode 100644
index 000000000000..146081779c39
--- /dev/null
+++ b/sys-cluster/libqb/libqb-0.14.4.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=4
+
+AUTOTOOLS_AUTORECONF=1
+
+inherit autotools-utils
+
+DESCRIPTION="Library providing high performance logging, tracing, ipc, and poll"
+HOMEPAGE="https://github.com/asalkeld/libqb"
+SRC_URI="http://fedorahosted.org/releases/q/u/quarterback/${P}.tar.xz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 hppa ~x86"
+IUSE="debug doc examples static-libs test"
+
+RDEPEND="dev-libs/glib:2"
+DEPEND="${RDEPEND}
+	app-arch/xz-utils
+	test? ( dev-libs/check )
+	doc? ( app-doc/doxygen[dot] )"
+
+DOCS=(README.markdown ChangeLog)
+
+src_prepare() {
+	sed -e '/dist_doc_DATA/d' -i Makefile.am || die
+	autotools-utils_src_prepare
+}
+
+src_configure() {
+	local myeconfargs=(
+		$(use_enable debug)
+	)
+	autotools-utils_src_configure
+}
+
+src_compile() {
+	autotools-utils_src_compile
+	use doc && autotools-utils_src_compile doxygen
+}
+
+src_install() {
+	use doc && HTML_DOCS=("${AUTOTOOLS_BUILD_DIR}/docs/html/")
+	autotools-utils_src_install
+	if use examples ; then
+		insinto /usr/share/doc/${PF}/examples
+		doins examples/*.c
+	fi
+}