blob: 155b209d25ad90eeee5150776d1f2a45c98887b9 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
|
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_USE_PEP517=setuptools
PYTHON_COMPAT=( python3_{10..12} )
inherit distutils-r1 optfeature
DESCRIPTION="Python library for serializing any arbitrary object graph into JSON"
HOMEPAGE="
https://github.com/jsonpickle/jsonpickle/
https://pypi.org/project/jsonpickle/
"
SRC_URI="
https://github.com/jsonpickle/jsonpickle/archive/refs/tags/v${PV}.tar.gz
-> ${P}.gh.tar.gz
"
LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~arm64 ~riscv ~x86 ~amd64-linux ~x86-linux"
BDEPEND="
dev-python/setuptools-scm[${PYTHON_USEDEP}]
test? (
dev-python/feedparser[${PYTHON_USEDEP}]
dev-python/gmpy[${PYTHON_USEDEP}]
dev-python/numpy[${PYTHON_USEDEP}]
dev-python/pandas[${PYTHON_USEDEP}]
dev-python/simplejson[${PYTHON_USEDEP}]
dev-python/sqlalchemy[${PYTHON_USEDEP}]
dev-python/ujson[${PYTHON_USEDEP}]
)
"
distutils_enable_tests pytest
python_prepare_all() {
local PATCHES=(
# https://github.com/jsonpickle/jsonpickle/pull/512
"${FILESDIR}/${P}-numpy-2.patch"
)
distutils-r1_python_prepare_all
sed -i -e 's:--cov::' pytest.ini || die
export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
}
python_test() {
local EPYTEST_IGNORE=(
# unpackaged bson dependency
tests/bson_test.py
)
if ! has_version "dev-python/gmpy[${PYTHON_USEDEP}]"; then
EPYTEST_IGNORE+=( jsonpickle/ext/gmpy.py )
fi
if ! has_version "dev-python/pandas[${PYTHON_USEDEP}]"; then
EPYTEST_IGNORE+=( jsonpickle/ext/pandas.py )
fi
epytest
}
pkg_postinst() {
# Unpackaged optional backends: yajl, demjson
optfeature "encoding numpy-based data" dev-python/numpy
optfeature "encoding pandas objects" dev-python/pandas
optfeature "fast JSON backend" dev-python/simplejson
}
|
GitWeb
