Version bump for Gnome 3.10, drop old

(Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key A188FBD4)

3 files changed, 100 insertions, 61 deletions

diff --git a/dev-libs/libpeas/ChangeLog b/dev-libs/libpeas/ChangeLog
index 45c3065de33f..fa571a861ff4 100644
--- a/dev-libs/libpeas/ChangeLog
+++ b/dev-libs/libpeas/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for dev-libs/libpeas
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/libpeas/ChangeLog,v 1.23 2013/12/08 18:04:37 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/libpeas/ChangeLog,v 1.24 2013/12/24 15:56:52 pacho Exp $
+
+*libpeas-1.9.0 (24 Dec 2013)
+
+  24 Dec 2013; Pacho Ramos <pacho@gentoo.org> +libpeas-1.9.0.ebuild,
+  -libpeas-1.6.2-r1.ebuild:
+  Version bump for Gnome 3.10, drop old
 
   08 Dec 2013; Pacho Ramos <pacho@gentoo.org> libpeas-1.8.1.ebuild:
   x86 stable, bug #478252
diff --git a/dev-libs/libpeas/libpeas-1.6.2-r1.ebuild b/dev-libs/libpeas/libpeas-1.6.2-r1.ebuild
deleted file mode 100644
index 3e2f458efbd0..000000000000
--- a/dev-libs/libpeas/libpeas-1.6.2-r1.ebuild
+++ /dev/null
@@ -1,60 +0,0 @@
-# Copyright 1999-2013 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/libpeas/libpeas-1.6.2-r1.ebuild,v 1.6 2013/02/02 22:26:12 ago Exp $
-
-EAPI="5"
-GCONF_DEBUG="no"
-GNOME2_LA_PUNT="yes"
-PYTHON_COMPAT=( python{2_6,2_7} )
-
-inherit eutils gnome2 multilib python-single-r1 virtualx
-
-DESCRIPTION="A GObject plugins library"
-HOMEPAGE="http://developer.gnome.org/libpeas/stable/"
-
-LICENSE="LGPL-2+"
-SLOT="0"
-IUSE="gjs +gtk glade +python seed"
-KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-freebsd ~x86-interix ~amd64-linux ~ia64-linux ~x86-linux"
-
-RDEPEND=">=dev-libs/glib-2.32:2
-	>=dev-libs/gobject-introspection-0.10.1
-	gjs? ( >=dev-libs/gjs-1.31.11 )
-	glade? ( >=dev-util/glade-3.9.1:3.10 )
-	gtk? ( >=x11-libs/gtk+-3:3[introspection] )
-	python? (
-		${PYTHON_DEPS}
-		>=dev-python/pygobject-3.0.0:3[${PYTHON_USEDEP}] )
-	seed? ( >=dev-libs/seed-2.91.91 )"
-DEPEND="${RDEPEND}
-	>=dev-util/intltool-0.40
-	>=sys-devel/gettext-0.17"
-
-pkg_setup() {
-	use python && python-single-r1_pkg_setup
-}
-
-src_prepare() {
-	G2CONF="${G2CONF}
-		$(use_enable gjs)
-		$(use_enable glade glade-catalog)
-		$(use_enable gtk)
-		$(use_enable python)
-		$(use_enable seed)
-		--disable-deprecation
-		--disable-static"
-	# Wtf, --disable-gcov, --enable-gcov=no, --enable-gcov, all enable gcov
-	# What do we do about gdb, valgrind, gcov, etc?
-
-	gnome2_src_prepare
-}
-
-src_test() {
-	# FIXME: Tests fail because of some bug involving Xvfb and Gtk.IconTheme
-	# DO NOT REPORT UPSTREAM, this is not a libpeas bug.
-	# To reproduce:
-	# >>> from gi.repository import Gtk
-	# >>> Gtk.IconTheme.get_default().has_icon("gtk-about")
-	# This should return True, it returns False for Xvfb
-	Xemake check
-}
diff --git a/dev-libs/libpeas/libpeas-1.9.0.ebuild b/dev-libs/libpeas/libpeas-1.9.0.ebuild
new file mode 100644
index 000000000000..614062fdd7a7
--- /dev/null
+++ b/dev-libs/libpeas/libpeas-1.9.0.ebuild
@@ -0,0 +1,93 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/libpeas/libpeas-1.9.0.ebuild,v 1.1 2013/12/24 15:56:52 pacho Exp $
+
+EAPI="5"
+GCONF_DEBUG="no"
+GNOME2_LA_PUNT="yes"
+PYTHON_COMPAT=( python{2_6,2_7,3_2,3_3} )
+
+inherit eutils gnome2 multilib python-r1 virtualx
+
+DESCRIPTION="A GObject plugins library"
+HOMEPAGE="http://developer.gnome.org/libpeas/stable/"
+
+LICENSE="LGPL-2+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~ppc ~ppc64 ~sparc ~x86 ~x86-freebsd ~x86-interix ~amd64-linux ~ia64-linux ~x86-linux"
+IUSE="gjs +gtk glade +python seed"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+RDEPEND="
+	>=dev-libs/glib-2.32:2
+	>=dev-libs/gobject-introspection-0.10.1
+	gjs? ( >=dev-libs/gjs-1.37.1 )
+	glade? ( >=dev-util/glade-3.9.1:3.10 )
+	gtk? ( >=x11-libs/gtk+-3:3[introspection] )
+	python? (
+		${PYTHON_DEPS}
+		>=dev-python/pygobject-3.0.0:3[${PYTHON_USEDEP}] )
+	seed? ( >=dev-libs/seed-2.91.91 )
+"
+DEPEND="${RDEPEND}
+	>=dev-util/gtk-doc-am-1.11
+	>=dev-util/intltool-0.40
+	>=sys-devel/gettext-0.17
+	virtual/pkgconfig
+"
+
+if_use_python_python_foreach_impl() {
+	if use python; then
+		python_foreach_impl run_in_build_dir "$@"
+	else
+		"$@"
+	fi
+}
+
+src_prepare() {
+	use python && python_copy_sources
+	if_use_python_python_foreach_impl gnome2_src_prepare
+}
+
+src_configure() {
+	local myconf="
+		$(use_enable gjs)
+		$(use_enable glade glade-catalog)
+		$(use_enable gtk)
+		$(use_enable seed)
+		--disable-deprecation
+		--disable-static"
+	# Wtf, --disable-gcov, --enable-gcov=no, --enable-gcov, all enable gcov
+	# What do we do about gdb, valgrind, gcov, etc?
+
+	configuration() {
+		local myconf="$@"
+		[[ ${EPYTHON} == python2* ]] && myconf+=" --enable-python2 --disable-python3 PYTHON2_CONFIG=/usr/bin/python-config-${EPYTHON#python}"
+		[[ ${EPYTHON} == python3* ]] && myconf+=" --enable-python3 --disable-python2 PYTHON3_CONFIG=/usr/bin/python-config-${EPYTHON#python}"
+		gnome2_src_configure ${myconf}
+	}
+
+	if use python; then
+		python_foreach_impl run_in_build_dir configuration ${myconf}
+	else
+		gnome2_src_configure ${myconf}
+	fi
+}
+
+src_compile() {
+	if_use_python_python_foreach_impl gnome2_src_compile
+}
+
+src_install() {
+	if_use_python_python_foreach_impl gnome2_src_install
+}
+
+src_test() {
+	# FIXME: Tests fail because of some bug involving Xvfb and Gtk.IconTheme
+	# DO NOT REPORT UPSTREAM, this is not a libpeas bug.
+	# To reproduce:
+	# >>> from gi.repository import Gtk
+	# >>> Gtk.IconTheme.get_default().has_icon("gtk-about")
+	# This should return True, it returns False for Xvfb
+	if_use_python_python_foreach_impl Xemake check
+}