Provide GTK+-3.0 version in SLOT="3"

(Portage version: 2.2.0_alpha77/cvs/Linux x86_64)

3 files changed, 160 insertions, 1 deletions

diff --git a/dev-libs/libindicate/ChangeLog b/dev-libs/libindicate/ChangeLog
index e09aeb883e86..1a4228bfbd64 100644
--- a/dev-libs/libindicate/ChangeLog
+++ b/dev-libs/libindicate/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for dev-libs/libindicate
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/libindicate/ChangeLog,v 1.24 2011/11/20 12:19:28 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/libindicate/ChangeLog,v 1.25 2011/11/26 18:10:45 ssuominen Exp $
+
+*libindicate-0.6.1-r300 (26 Nov 2011)
+*libindicate-0.6.1-r201 (26 Nov 2011)
+
+  26 Nov 2011; Samuli Suominen <ssuominen@gentoo.org>
+  +libindicate-0.6.1-r201.ebuild, +libindicate-0.6.1-r300.ebuild:
+  Provide GTK+-3.0 version in SLOT="3"
 
   20 Nov 2011; Samuli Suominen <ssuominen@gentoo.org> metadata.xml:
   Maintained by both ayatana and kde.
diff --git a/dev-libs/libindicate/libindicate-0.6.1-r201.ebuild b/dev-libs/libindicate/libindicate-0.6.1-r201.ebuild
new file mode 100644
index 000000000000..31e7476d4eb8
--- /dev/null
+++ b/dev-libs/libindicate/libindicate-0.6.1-r201.ebuild
@@ -0,0 +1,90 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/libindicate/libindicate-0.6.1-r201.ebuild,v 1.1 2011/11/26 18:10:45 ssuominen Exp $
+
+EAPI=4
+
+PYTHON_DEPEND="2:2.7"
+
+inherit autotools eutils python
+
+PV_vala_version=0.14
+
+DESCRIPTION="A library to raise flags on DBus for other components of the desktop to pick up and visualize"
+HOMEPAGE="http://launchpad.net/libindicate"
+SRC_URI="http://launchpad.net/${PN}/${PV%.*}/${PV}/+download/${P}.tar.gz"
+
+LICENSE="LGPL-2.1 LGPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+introspection"
+
+# note: pull in SLOT="3" to install headers and libs (see rm -rf in src_install)
+RDEPEND=">=dev-libs/dbus-glib-0.76
+	>=dev-libs/glib-2.18:2
+	>=dev-libs/libdbusmenu-0.3.97[introspection?]
+	dev-libs/libxml2:2
+	dev-python/pygtk:2
+	>=x11-libs/gtk+-2.12:2
+	${CATEGORY}/${PN}:3
+	introspection? ( dev-libs/gobject-introspection )"
+DEPEND="${RDEPEND}
+	gnome-base/gnome-common
+	app-text/gnome-doc-utils
+	dev-util/gtk-doc-am
+	dev-util/pkgconfig
+	dev-lang/vala:${PV_vala_version}[vapigen]
+	!<${CATEGORY}/${PN}-0.6.1-r201"
+
+RESTRICT="test" # for -no-mono.patch
+
+pkg_setup() {
+	python_set_active_version 2
+	python_pkg_setup
+}
+
+src_prepare() {
+	epatch "${FILESDIR}"/${P}-no-mono.patch
+
+	sed -i -e 's:-Werror::' {examples,libindicate,libindicate-gtk}/Makefile.{am,in} || die
+
+	# for slotted dev-lang/vala
+	sed -i -e "s:vapigen:vapigen-${PV_vala_version}:" configure.ac || die
+
+	eautoreconf
+
+	rm -f py-compile
+	ln -s $(type -P true) py-compile
+}
+
+src_configure() {
+	econf \
+		--disable-static \
+		$(use_enable introspection) \
+		--with-gtk=2
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+	find "${ED}"usr -name '*.la' -exec rm -f {} +
+
+	# note: purposely not installing documentation and colliding files to
+	# support SLOT="3"
+	rm -rf \
+		"${ED}"usr/include/${PN}-0.6/${PN}* \
+		"${ED}"usr/share/doc \
+		"${ED}"usr/share/gir-1.0/Indicate-0.6.gir \
+		"${ED}"usr/share/gtk-doc \
+		"${ED}"usr/share/vala/vapi/Indicate-0.6.vapi \
+		"${ED}"usr/lib*/girepository-1.0/Indicate-0.6.typelib \
+		"${ED}"usr/lib*/${PN}.so* \
+		"${ED}"usr/lib*/pkgconfig/indicate-0.6.pc
+}
+
+pkg_postinst() {
+	python_mod_optimize indicate
+}
+
+pkg_postrm() {
+	python_mod_cleanup indicate
+}
diff --git a/dev-libs/libindicate/libindicate-0.6.1-r300.ebuild b/dev-libs/libindicate/libindicate-0.6.1-r300.ebuild
new file mode 100644
index 000000000000..c0da735220d7
--- /dev/null
+++ b/dev-libs/libindicate/libindicate-0.6.1-r300.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/libindicate/libindicate-0.6.1-r300.ebuild,v 1.1 2011/11/26 18:10:45 ssuominen Exp $
+
+EAPI=4
+inherit autotools eutils
+
+PV_vala_version=0.14
+
+DESCRIPTION="A library to raise flags on DBus for other components of the desktop to pick up and visualize"
+HOMEPAGE="http://launchpad.net/libindicate"
+SRC_URI="http://launchpad.net/${PN}/${PV%.*}/${PV}/+download/${P}.tar.gz"
+
+LICENSE="LGPL-2.1 LGPL-3"
+SLOT="3"
+KEYWORDS="~amd64 ~x86"
+IUSE="+introspection"
+
+RDEPEND=">=dev-libs/dbus-glib-0.76
+	>=dev-libs/glib-2.18:2
+	>=dev-libs/libdbusmenu-0.3.97[introspection?]
+	dev-libs/libxml2:2
+	x11-libs/gtk+:3
+	introspection? ( dev-libs/gobject-introspection )"
+DEPEND="${RDEPEND}
+	gnome-base/gnome-common
+	app-text/gnome-doc-utils
+	dev-util/gtk-doc-am
+	dev-util/pkgconfig
+	dev-lang/vala:${PV_vala_version}[vapigen]
+	!<${CATEGORY}/${PN}-0.6.1-r201"
+
+RESTRICT="test" # for -no-mono.patch
+
+DOCS=( AUTHORS ChangeLog )
+
+src_prepare() {
+	epatch "${FILESDIR}"/${P}-no-mono.patch
+
+	sed -i -e 's:-Werror::' {examples,libindicate,libindicate-gtk}/Makefile.{am,in} || die
+
+	# for slotted dev-lang/vala
+	sed -i -e "s:vapigen:vapigen-${PV_vala_version}:" configure.ac || die
+
+	eautoreconf
+}
+
+src_configure() {
+	# note: --disable-python to avoid automagic gtk+-2.0 usage
+	econf \
+		--docdir=/usr/share/doc/${PF} \
+		--disable-static \
+		$(use_enable introspection) \
+		--disable-python \
+		--with-gtk=3 \
+		--with-html-dir=/usr/share/doc/${PF}
+}
+
+src_install() {
+	default
+	find "${ED}"usr -name '*.la' -exec rm -f {} +
+}