blob: c8e0aee63ef2cfe9b8ce06aa3c2f2c68e2c22ebc (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
|
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-libs/gnutls/gnutls-2.11.0.ebuild,v 1.1 2010/07/22 20:13:14 arfrever Exp $
EAPI="3"
inherit autotools libtool
DESCRIPTION="A TLS 1.2 and SSL 3.0 implementation for the GNU project"
HOMEPAGE="http://www.gnutls.org/"
if [[ "${PV}" == *pre* ]]; then
SRC_URI="http://daily.josefsson.org/${P%.*}/${P%.*}-${PV#*pre}.tar.gz"
else
MINOR_VERSION="${PV#*.}"
MINOR_VERSION="${MINOR_VERSION%.*}"
if [[ $((MINOR_VERSION % 2)) == 0 ]]; then
#SRC_URI="ftp://ftp.gnu.org/pub/gnu/${PN}/${P}.tar.bz2"
SRC_URI="mirror://gnu/${PN}/${P}.tar.bz2"
else
#SRC_URI="ftp://alpha.gnu.org/gnu/${PN}/${P}.tar.bz2"
SRC_URI="ftp://ftp.gnutls.org/pub/${PN}/devel/${P}.tar.bz2"
fi
unset MINOR_VERSION
fi
# GPL-3 for the gnutls-extras library and LGPL for the gnutls library.
LICENSE="LGPL-2.1 GPL-3"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~sparc-fbsd ~x86-fbsd"
IUSE="bindist +cxx doc examples guile lzo nls test valgrind zlib"
RDEPEND="dev-libs/libgpg-error
>=dev-libs/libgcrypt-1.4.0
>=dev-libs/libtasn1-0.3.4
nls? ( virtual/libintl )
guile? ( dev-scheme/guile[networking] )
zlib? ( >=sys-libs/zlib-1.1 )
!bindist? ( lzo? ( >=dev-libs/lzo-2 ) )"
DEPEND="${RDEPEND}
sys-devel/libtool
doc? ( dev-util/gtk-doc )
nls? ( sys-devel/gettext )
test? ( valgrind? ( dev-util/valgrind ) )"
S="${WORKDIR}/${P%_pre*}"
pkg_setup() {
if use lzo && use bindist; then
ewarn "lzo support was disabled for binary distribution of GnuTLS"
ewarn "due to licensing issues. See Bug #202381 for details."
fi
}
src_prepare() {
sed -e 's/imagesdir = $(infodir)/imagesdir = $(htmldir)/' -i \
doc/Makefile.am || die
local dir
for dir in m4 lib/m4 libextra/m4; do
rm -f "${dir}/lt"* "${dir}/libtool.m4"
done
find . -name ltmain.sh -exec rm {} \;
for dir in . lib libextra; do
pushd "${dir}" > /dev/null
eautoreconf
popd > /dev/null
done
elibtoolize # for sane .so versioning on FreeBSD
}
src_configure() {
local myconf
use bindist && myconf="--without-lzo" || myconf="$(use_with lzo)"
econf --htmldir=/usr/share/doc/${P}/html \
$(use_enable cxx) \
$(use_enable doc gtk-doc) \
$(use_enable guile) \
$(use_enable nls) \
$(use_enable valgrind valgrind-tests)\
$(use_with zlib) \
${myconf}
}
src_install() {
emake DESTDIR="${D}" install || die "emake install failed"
dodoc AUTHORS ChangeLog NEWS README THANKS doc/TODO || die
if use doc; then
dodoc doc/gnutls.{pdf,ps} || die
dohtml doc/gnutls.html || die
fi
if use examples; then
docinto examples
dodoc doc/examples/*.c || die
fi
}
|
GitWeb