gimp-2.8.10-r1 from gentoo

2 files changed, 166 insertions, 0 deletions

diff --git a/media-gfx/gimp/Manifest b/media-gfx/gimp/Manifest
index ff03d47..b8b56c0 100644
--- a/media-gfx/gimp/Manifest
+++ b/media-gfx/gimp/Manifest
@@ -1,5 +1,8 @@
 AUX gimp-2.7.4-no-deprecation.patch 1061 SHA256 fb9532406b62a6fa12f8598b142186fad1dc4e937328c8859cb4e8e76d2b19c7 SHA512 3454f3b1a7579b1da4c36b765ae2a54adab13f0a4ecf02c4c0c3c55a12ff7af57d6d0467f663d2ef3de6cda116095f5f662a29cb3d729e0533edd585731a1dc9 WHIRLPOOL 25b645c7e3f39cabe35155dd24c061a088a1800b0a4c154196ff89f4ccf3fc1950a1028d08eddf879cc482ca334bd99bc4c6cea8288e3bf36c0bed657485d984
+DIST gimp-2.8.10-freetype251.patch 679 SHA256 34d1b729e267d33084c19fc89f7e125cd49ed4586b07794b169d5fe22d98f970 SHA512 e6c9271d8de9cd549bef666254724c644cef88291c7590e86d98dae444f808002f6bdb2400a3a44a65396f8b169b2a8c2985d6f169b295de8c3d14732013e053 WHIRLPOOL 500fae1f3e8b5a4eec039662f896fa5a0b3083dfe0b83ac5b97fe99ca4aaebe007f0fb88bc03dcb554e3c8e7f006a7355448f4f6477c02f894358da2d2a155b6
+DIST gimp-2.8.10.tar.bz2 20343461 SHA256 e7fd8b19f989138d826003c75f56bd5b6f136eef597e86e3978ede0bba470ae6 SHA512 21c96832ce61ecb2dad5276b454e7965263b6733add7e4a95cfc5f308fca681bceab21c1b77921332e0725d0e514e06868a4698ca9d7e4b30a28a07c7356a3a8 WHIRLPOOL 16b0a7e8a4197db41da29832977bee917e65d5cbbf308dde1ba73c150742c70c52cd60d449d0fd0269b0ed5db0378461d3277a2350898c3a5e07b1f3cf8bdf47
 DIST gimp-2.8.8.tar.bz2 20345808 SHA256 74c4509bae55f07140bc46f16100fc1e0e052829c13d4d87dc31d07d3e696a67 SHA512 3c841c1d11ac41eb5a4ae9d039c339d91eec7b05a303efa6a10ea9cb1af3d56c9b8a55f752c8f4c50ddddca3fbe220949d6e22838c71d5f9dfba9fab922bf8c3 WHIRLPOOL b3c3f33449bb14dfed34189ec674c9b7fb52c52a5ab2ddf6bb481fe921aeaa7e5cd8de9107767d9a61476da1f9c6d6f15464372bad11e112739eb4216002e3f0
+EBUILD gimp-2.8.10-r1.ebuild 4754 SHA256 528c95bae5323b0e24891d07ffea0a7d1858fe615119f56a982803189f330493 SHA512 c1e4f91dc89ca1886052b00bda002c4084f3304b5cfb9c0de1598fd63d6f1b6a8a968e1bb14616af9cfccd382e939478c68721c17f592e8b01a02237a763207a WHIRLPOOL 48ba0e913a21c1feeb258e382f31d608923fc69c5cec1a1fb98bdb171807e73d8a514fab4cd7f6a8d56a717b16ab9db3b455edcdb846841dc70d5daba3cde182
 EBUILD gimp-2.8.8-r1.ebuild 4868 SHA256 a0eaa9ef8a5975dcd491ee27d8fc2b08502be45efb16bb1495d6bd1e159634aa SHA512 5ab8df2b8f9c65d0a7caace0da11989f8e4ec6552c33fa160759eff3e1ded49c1bcb924f4cf3dbd49e8af8251bcfec1a86238007b0b9feddfc11acfe2b205124 WHIRLPOOL 095f8bb7810d26d7611a386aa470e2839aa5b5076b99f58cf5b1026314f24120c11fffda3c4559719d0deeae492b6b6cf42a9b08812f96febbb191fad9196525
 EBUILD gimp-2.8.8.ebuild 4866 SHA256 0ef460fe27419df8ae21dc3d99773944f980c4ffa55a3d92519c757fa9fa8def SHA512 5c54fc1ebcb153078b25ef288f4ff4b7c55c699fa02a0b6cf3dd807cf070b4efe8ba5488b062935617f2b68c672642f9f15318485711e960606c7da0a7f86a66 WHIRLPOOL 769e909a652aed104aac33a2da40203b1b6cbb58b9db638827c4826ec36f3b14e9aaba3e4ac07b70aa672a095bfcad09a4dc04d57bb7b9c02e301422ffba9bff
 MISC metadata.xml 285 SHA256 77c9767711868abab1e559504dd88eb8aef8cf395629d8ec8c7a5fdb3d29397e SHA512 0b1abe9749d79ed8644c2a34312ab70cff232e08f64c1a914185cbafe8c754e9c6442eac1e3a1c449057e52b076333b70ea8be7418570bfcbee69f69d455079e WHIRLPOOL 9f2199f149dd49efce83f4710f026fc235a9aed38b7c7e0ffbb5480ef6865dee6ac555178bb92a819071d016fb0ead581765697cc3035b829ed96126bc7e6053
diff --git a/media-gfx/gimp/gimp-2.8.10-r1.ebuild b/media-gfx/gimp/gimp-2.8.10-r1.ebuild
new file mode 100644
index 0000000..33c8d6b
--- /dev/null
+++ b/media-gfx/gimp/gimp-2.8.10-r1.ebuild
@@ -0,0 +1,163 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/gimp/gimp-2.8.10-r1.ebuild,v 1.1 2013/12/10 09:12:09 polynomial-c Exp $
+
+EAPI=5
+PYTHON_COMPAT=( python2_{6,7} )
+
+inherit versionator autotools eutils gnome2 fdo-mime multilib python-single-r1
+
+DESCRIPTION="GNU Image Manipulation Program"
+HOMEPAGE="http://www.gimp.org/"
+SRC_URI="mirror://gimp/v$(get_version_component_range 1-2)/${P}.tar.bz2
+	https://git.gnome.org/browse/gimp/patch/?id=6c73f28b6d87a2afd11974552a075bffec52347f -> ${P}-freetype251.patch"
+LICENSE="GPL-3 LGPL-3"
+SLOT="2"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-interix ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~x64-solaris ~x86-solaris"
+
+LANGS="am ar ast az be bg br ca ca@valencia cs csb da de dz el en_CA en_GB eo es et eu fa fi fr ga gl gu he hi hr hu id is it ja ka kk km kn ko lt lv mk ml ms my nb nds ne nl nn oc pa pl pt pt_BR ro ru rw si sk sl sr sr@latin sv ta te th tr tt uk vi xh yi zh_CN zh_HK zh_TW"
+IUSE="alsa aalib altivec aqua bzip2 curl dbus debug doc exif gnome postscript jpeg jpeg2k lcms mmx mng pdf png python smp sse svg tiff udev webkit wmf xpm"
+
+for lang in ${LANGS}; do
+	IUSE+=" linguas_${lang}"
+done
+
+RDEPEND=">=dev-libs/glib-2.30.2:2
+	>=dev-libs/atk-2.2.0
+	>=x11-libs/gtk+-2.24.10:2
+	>=x11-libs/gdk-pixbuf-2.24.1:2
+	>=x11-libs/cairo-1.10.2
+	>=x11-libs/pango-1.29.4
+	xpm? ( x11-libs/libXpm )
+	>=media-libs/freetype-2.1.7
+	>=media-libs/fontconfig-2.2.0
+	sys-libs/zlib
+	dev-libs/libxml2
+	dev-libs/libxslt
+	x11-themes/hicolor-icon-theme
+	>=media-libs/babl-0.1.10
+	>=media-libs/gegl-0.2.0
+	aalib? ( media-libs/aalib )
+	alsa? ( media-libs/alsa-lib )
+	curl? ( net-misc/curl )
+	dbus? ( dev-libs/dbus-glib )
+	gnome? ( gnome-base/gvfs )
+	webkit? ( >=net-libs/webkit-gtk-1.6.1:2 )
+	jpeg? ( virtual/jpeg:0 )
+	jpeg2k? ( media-libs/jasper )
+	exif? ( >=media-libs/libexif-0.6.15 )
+	lcms? ( >=media-libs/lcms-2.2:2 )
+	mng? ( media-libs/libmng )
+	pdf? ( >=app-text/poppler-0.12.4[cairo] )
+	png? ( >=media-libs/libpng-1.2.37:0 )
+	python?	(
+		${PYTHON_DEPS}
+		>=dev-python/pygtk-2.10.4:2[${PYTHON_USEDEP}]
+	)
+	tiff? ( >=media-libs/tiff-3.5.7:0 )
+	svg? ( >=gnome-base/librsvg-2.36.0:2 )
+	wmf? ( >=media-libs/libwmf-0.2.8 )
+	x11-libs/libXcursor
+	sys-libs/zlib
+	bzip2? ( app-arch/bzip2 )
+	postscript? ( app-text/ghostscript-gpl )
+	udev? ( virtual/udev[gudev] )"
+DEPEND="${RDEPEND}
+	sys-apps/findutils
+	virtual/pkgconfig
+	>=dev-util/intltool-0.40.1
+	>=sys-devel/gettext-0.17
+	doc? ( >=dev-util/gtk-doc-1 )
+	>=sys-devel/libtool-2.2
+	>=sys-devel/automake-1.11
+	dev-util/gtk-doc-am"  # due to our call to eautoreconf below (bug #386453)
+
+DOCS="AUTHORS ChangeLog* HACKING NEWS README*"
+
+S="${WORKDIR}"/${P}
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+pkg_setup() {
+	G2CONF="--enable-default-binary \
+		--disable-silent-rules \
+		$(use_with !aqua x) \
+		$(use_with aalib aa) \
+		$(use_with alsa) \
+		$(use_enable altivec) \
+		$(use_with bzip2) \
+		$(use_with curl libcurl) \
+		$(use_with dbus) \
+		$(use_with gnome gvfs) \
+		$(use_with webkit) \
+		$(use_with jpeg libjpeg) \
+		$(use_with jpeg2k libjasper) \
+		$(use_with exif libexif) \
+		$(use_with lcms lcms lcms2) \
+		$(use_with postscript gs) \
+		$(use_enable mmx) \
+		$(use_with mng libmng) \
+		$(use_with pdf poppler) \
+		$(use_with png libpng) \
+		$(use_enable python) \
+		$(use_enable smp mp) \
+		$(use_enable sse) \
+		$(use_with svg librsvg) \
+		$(use_with tiff libtiff) \
+		$(use_with udev gudev) \
+		$(use_with wmf) \
+		--with-xmc \
+		$(use_with xpm libxpm) \
+		--without-xvfb-run"
+
+	if use python; then
+		python-single-r1_pkg_setup
+	fi
+}
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-2.7.4-no-deprecation.patch  # bug 395695, comment 9 and 16
+	epatch "${DISTDIR}"/${P}-freetype251.patch # bug #493466
+	eautoreconf  # If you remove this: remove dev-util/gtk-doc-am from DEPEND, too
+
+	gnome2_src_prepare
+}
+
+_clean_up_locales() {
+	einfo "Cleaning up locales..."
+	for lang in ${LANGS}; do
+		use "linguas_${lang}" && {
+			einfo "- keeping ${lang}"
+			continue
+		}
+		rm -Rf "${ED}"/usr/share/locale/"${lang}" || die
+	done
+}
+
+src_install() {
+	gnome2_src_install
+
+	if use python; then
+		python_optimize
+	fi
+
+	# Workaround for bug #321111 to give GIMP the least
+	# precedence on PDF documents by default
+	mv "${ED}"/usr/share/applications/{,zzz-}gimp.desktop || die
+
+	prune_libtool_files --all
+
+	# Prevent dead symlink gimp-console.1 from downstream man page compression (bug #433527)
+	local gimp_app_version=$(get_version_component_range 1-2)
+	mv "${ED}"/usr/share/man/man1/gimp-console{-${gimp_app_version},}.1 || die
+
+	_clean_up_locales
+}
+
+pkg_postinst() {
+	gnome2_pkg_postinst
+}
+
+pkg_postrm() {
+	gnome2_pkg_postrm
+}