Version bump wrt#453194

Package-Manager: portage-2.1.11.31
Manifest-Sign-Key: 9BF3548C

1 files changed, 50 insertions, 0 deletions

diff --git a/dev-java/jgoodies-common/jgoodies-common-1.4.0.ebuild b/dev-java/jgoodies-common/jgoodies-common-1.4.0.ebuild
new file mode 100644
index 0000000..73a31ef
--- /dev/null
+++ b/dev-java/jgoodies-common/jgoodies-common-1.4.0.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=4
+JAVA_PKG_IUSE="doc source"
+
+inherit java-pkg-2 java-ant-2 eutils
+
+MY_PN="common"
+MY_PV=${PV//./_}
+MY_P="${PN}-${MY_PV}"
+DESCRIPTION="JGoodies Common Library"
+HOMEPAGE="http://www.jgoodies.com/"
+SRC_URI="http://www.jgoodies.com/download/libraries/${MY_PN}/${MY_P}.zip"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE=""
+
+DEPEND=">=virtual/jdk-1.6
+	app-arch/unzip"
+RDEPEND=">=virtual/jre-1.6"
+
+src_unpack() {
+	default
+	cd "${S}"
+	mkdir src && cd src &&  unzip -qq ../${P}-sources.jar || die
+	find "${S}" -name '*.jar' -exec rm -v {} +
+}
+
+src_compile() {
+	mkdir "${S}/classes"
+
+	find src -name "*.java" > "${T}/src.list"
+	ejavac -encoding ISO-8859-1 -d "${S}/classes" "@${T}/src.list"
+
+	cd "${S}/classes"
+	jar -cf "${S}/${PN}.jar" * || die "failed to create jar"
+}
+
+src_install() {
+	java-pkg_dojar ${PN}.jar
+
+	dodoc RELEASE-NOTES.txt README.html || die
+
+	use doc && java-pkg_dohtml -r docs/*
+	use source && java-pkg_dosrc src
+}