Add ebuild to sddm-9999-r1

2 files changed, 73 insertions, 0 deletions

diff --git a/x11-misc/sddm/Manifest b/x11-misc/sddm/Manifest
new file mode 100644
index 0000000..bbce117
--- /dev/null
+++ b/x11-misc/sddm/Manifest
@@ -0,0 +1 @@
+EBUILD sddm-9999-r1.ebuild 1876 SHA256 6ea977f7c5ccda2b10928a0f11940561db91edbb0bf8c1c92f675fa19fca1aed SHA512 ceb11de6c328f7ce6bf635cc6f368b352e6d4f1d8f24ac9b68a84fb1605ba8f65c648796a466fbe7c33bc43fbbf33bd7e36ceb609890c1a9c926d58f5c9974a1 WHIRLPOOL a4e0c2a5a41a26f245db21784e885c384abfd8f3672a80bacce9e720568b628b8f3ddbaee306233d9f11b46edb4e487492e49be712060f2e26a60b50f1624e5a
diff --git a/x11-misc/sddm/sddm-9999-r1.ebuild b/x11-misc/sddm/sddm-9999-r1.ebuild
new file mode 100644
index 0000000..11dcd1b
--- /dev/null
+++ b/x11-misc/sddm/sddm-9999-r1.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+inherit cmake-utils git-r3 toolchain-funcs user
+
+DESCRIPTION="Simple Desktop Display Manager"
+HOMEPAGE="https://github.com/sddm/sddm"
+EGIT_REPO_URI="git://github.com/${PN}/${PN}.git"
+KEYWORDS=""
+
+LICENSE="GPL-2+ MIT CC-BY-3.0 public-domain"
+SLOT="0"
+IUSE="doc consolekit systemd +upower"
+REQUIRED_USE="?? ( upower systemd )"
+
+RDEPEND="sys-libs/pam
+	x11-libs/libxcb[xkb(-)]
+	dev-qt/qtcore:5
+	dev-qt/qtdbus:5
+	dev-qt/qtdeclarative:5
+	dev-qt/linguist-tools:5
+	dev-qt/qttest:5
+	systemd? ( sys-apps/systemd:= )
+	upower? ( || ( sys-power/upower sys-power/upower-pm-utils ) )"
+DEPEND="${RDEPEND}
+	>=sys-devel/gcc-4.7.0
+	virtual/pkgconfig"
+
+pkg_pretend() {
+	if [[ ${MERGE_TYPE} != binary ]]; then
+		[[ $(gcc-version) < 4.7 ]] && \
+			die 'The active compiler needs to be gcc 4.7 (or newer)'
+	fi
+}
+
+src_prepare() {
+	use consolekit && epatch "${FILESDIR}/${P}-consolekit.patch"
+
+	# respect user's cflags
+	sed -e 's|-Wall -march=native||' \
+		-e 's|-O2||' \
+		-i CMakeLists.txt || die 'sed failed'
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake-utils_use_no systemd SYSTEMD)
+	)
+	if use doc; then
+		mycmakeargs+=( "-DBUILD_MAN_PAGES=ON" )
+	fi
+	cmake-utils_src_configure
+}
+
+pkg_postinst() {
+	if use consolekit; then
+		ewarn "This display manager doesn't have native built-in ConsoleKit support."
+		ewarn "In order to use ConsoleKit pam module with this display manager,"
+		ewarn "you should remove the \"nox11\" parameter from pm_ck_connector.so"
+		ewarn "line in /etc/pam.d/system-login"
+	fi
+	ewarn "Add the sddm user manually to the video group"
+	ewarn "if you experience flickering or other rendering issues of sddm-greeter"
+	ewarn "see https://github.com/gentoo/qt/pull/52"
+}
+
+pkg_setup() {
+	enewgroup ${PN}
+	enewuser ${PN} -1 -1 /var/lib/sddm ${PN}
+}