3 files changed, 98 insertions, 0 deletions
diff --git a/dev-python/graph-tool/Manifest b/dev-python/graph-tool/Manifest
new file mode 100644
index 0000000..488e24c
--- /dev/null
+++ b/dev-python/graph-tool/Manifest
@@ -0,0 +1,3 @@
+DIST graph-tool-2.79.tar.xz 15014436 BLAKE2B 74a86a7335aeda35040d8f1aabce9a2701caa6930f7556016fe23e3b27c4cae40cd289ee4727c5e9803b84bdb25d30cda2fbda24627cd3fbe613264dcdd44cf2 SHA512 42ca3f1ff88494b59d4f44dd664dbe940baa8e1d9550aaabeffb6bd5289c35b67df2d44d85c32f1c6b5cfd2b3af8e0a737b9428383cad233589a5d0d152aab14
+EBUILD graph-tool-2.79.ebuild 1778 BLAKE2B 7249b7e5d6ffbccf5967287ccf3e5ccd24b6e90300485ca623e99bb91e01c8f5316901c01d7b90b0d5468d41331dd73b2503c1339362fe19185eb31bf9cf2ee8 SHA512 75f70b1688eac59bbfadc826c70808bcb9325b23d8c7eae16b6cddffbc66ee372b48e3b96ac41d6d093fd76f0503b7774f2457e4b65a133a393c05ad99ffa9e0
+MISC metadata.xml 325 BLAKE2B c74eb70f001576a5ffcf1b1bc3efbce1abce332ce42cffd6173d24ae066182baedda99d39b82c4e32d8d18c533753dcfc1daf81cc19c1eb67522cfc12a5d56a8 SHA512 4078ae756e82d4f74bda8c7410ea1e31980cd8566b211013446b0d67ab9bc4b949d57fe1796e847e23309d072dcad8a853341d278239daea2e1b4ec924a4b73b
diff --git a/dev-python/graph-tool/graph-tool-2.79.ebuild b/dev-python/graph-tool/graph-tool-2.79.ebuild
new file mode 100644
index 0000000..933f090
--- /dev/null
+++ b/dev-python/graph-tool/graph-tool-2.79.ebuild
@@ -0,0 +1,84 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit check-reqs python-r1 toolchain-funcs
+
+if [[ ${PV} == *9999 ]]; then
+	EGIT_REPO_URI="https://git.skewed.de/count0/graph-tool.git"
+	inherit autotools git-r3
+else
+	SRC_URI="https://downloads.skewed.de/${PN}/${P}.tar.xz"
+	KEYWORDS="~amd64"
+fi
+
+DESCRIPTION="An efficient python module for manipulation and statistical analysis of graphs"
+HOMEPAGE="https://graph-tool.skewed.de/"
+
+LICENSE="GPL-3"
+SLOT="0"
+IUSE="+cairo openmp"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="
+	${PYTHON_DEPS}
+	dev-libs/boost:=[context,python,${PYTHON_USEDEP}]
+	dev-libs/expat
+	dev-python/numpy[${PYTHON_USEDEP}]
+	dev-python/scipy[${PYTHON_USEDEP}]
+	sci-mathematics/cgal:=
+	dev-python/matplotlib[${PYTHON_USEDEP}]
+	cairo? (
+		dev-cpp/cairomm:0
+		dev-python/pycairo[${PYTHON_USEDEP}]
+		x11-libs/cairo[X]
+	)"
+DEPEND="${RDEPEND}
+	dev-cpp/sparsehash"
+BDEPEND="virtual/pkgconfig"
+
+# bug 453544
+CHECKREQS_DISK_BUILD="6G"
+
+pkg_pretend() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+	check-reqs_pkg_pretend
+}
+
+pkg_setup() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+}
+
+src_prepare() {
+	default
+	[[ ${PV} == *9999 ]] && eautoreconf
+	python_copy_sources
+}
+
+src_configure() {
+	my_configure() {
+		econf \
+			--disable-static \
+			$(use_enable openmp) \
+			$(use_enable cairo) \
+			--with-boost-python="boost_${EPYTHON/./}"
+	}
+	python_foreach_impl run_in_build_dir my_configure
+}
+
+src_compile() {
+	python_foreach_impl run_in_build_dir emake
+}
+
+src_install() {
+	my_python_install() {
+		default
+		python_optimize
+	}
+	python_foreach_impl run_in_build_dir my_python_install
+
+	find "${ED}" -name '*.la' -delete || die
+}
diff --git a/dev-python/graph-tool/metadata.xml b/dev-python/graph-tool/metadata.xml
new file mode 100644
index 0000000..991e9cc
--- /dev/null
+++ b/dev-python/graph-tool/metadata.xml
@@ -0,0 +1,11 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>gerion.entrup@flump.de</email>
+		<name>Gerion Entrup</name>
+	</maintainer>
+	<upstream>
+		<remote-id type="pypi">graph-tool</remote-id>
+	</upstream>
+</pkgmetadata>