blob: dbc447ba9919ae1ebec791ba33325a8c50a75c46 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
|
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit xdg-utils
DESCRIPTION="A panel plug-in for acpi, lm-sensors and hddtemp sensors"
HOMEPAGE="https://goodies.xfce.org/projects/panel-plugins/xfce4-sensors-plugin"
SRC_URI="https://archive.xfce.org/src/panel-plugins/${PN}/${PV%.*}/${P}.tar.bz2"
LICENSE="GPL-2+"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
IUSE="+acpi hddtemp libnotify lm-sensors video_cards_nvidia"
REQUIRED_USE="|| ( hddtemp lm-sensors acpi )"
RDEPEND=">=x11-libs/gtk+-3.20:3=
>=xfce-base/libxfce4ui-4.14:=
>=xfce-base/libxfce4util-4.14:=
>=xfce-base/xfce4-panel-4.12:=
hddtemp? (
app-admin/hddtemp
|| (
net-analyzer/openbsd-netcat
net-analyzer/netcat
)
)
libnotify? ( >=x11-libs/libnotify-0.7:= )
lm-sensors? ( >=sys-apps/lm-sensors-3.1.0:= )
video_cards_nvidia? ( x11-drivers/nvidia-drivers[tools,static-libs] )"
DEPEND=${RDEPEND}
BDEPEND="
dev-util/intltool
virtual/pkgconfig"
src_configure() {
local myconf=(
--libexecdir="${EPREFIX}"/usr/$(get_libdir)
$(use_enable lm-sensors libsensors)
$(use_enable hddtemp)
$(use_enable hddtemp netcat)
$(use_enable acpi procacpi)
$(use_enable acpi sysfsacpi)
$(use_enable video_cards_nvidia xnvctrl)
$(use_enable libnotify notification)
--disable-pathchecks
)
econf "${myconf[@]}"
}
src_install() {
default
find "${D}" -name '*.la' -delete || die
}
pkg_postinst() {
xdg_icon_cache_update
}
pkg_postrm() {
xdg_icon_cache_update
}
|
GitWeb
