blob: f87a29dadb4ba2417d780edf1377ce8fc084d388 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
|
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit autotools desktop flag-o-matic virtualx
DESCRIPTION="Program suite to record, replay and distribute user actions"
HOMEPAGE="https://xnee.wordpress.com/"
SRC_URI="mirror://gnu/${PN}/${P}.tar.gz"
LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="gnome xosd"
RDEPEND="
x11-libs/libX11
x11-libs/libXau
x11-libs/libXdmcp
x11-libs/libXext
x11-libs/libXi
x11-libs/libXtst
x11-libs/libxcb
gnome? (
>=gnome-base/gconf-2
x11-libs/gtk+:2
)
"
DEPEND="${RDEPEND}
x11-base/xorg-proto
"
BDEPEND="
virtual/pkgconfig
sys-devel/gettext
gnome? ( virtual/imagemagick-tools[jpeg,png] )
"
# This needs RECORD extension from X.org server which isn't necessarily
# enabled. Xlib: extension "RECORD" missing on display ":0.0".
RESTRICT="test"
DOCS=( AUTHORS BUGS ChangeLog FAQ NEWS README TODO )
PATCHES=(
"${FILESDIR}"/${PN}-3.18-linker.patch
"${FILESDIR}"/${P}-libgnomeui-only-for-applets.patch
"${FILESDIR}"/${P}-slibtool.patch
)
src_prepare() {
default
mv configure.{in,ac} || die
eautoreconf
}
src_configure() {
append-cflags -fcommon
econf \
$(use_enable gnome gui) \
$(use_enable xosd buffer_verbose) \
$(use_enable xosd verbose) \
$(use_enable xosd) \
--disable-gnome-applet \
--disable-static \
--disable-static-programs \
--enable-cli \
--enable-lib
}
src_test() {
virtx emake check
}
src_install() {
default
use gnome && make_desktop_entry gnee Gnee ${PN} "Utility;GTK"
find "${ED}" -name '*.la' -delete || die
}
|
GitWeb