blob: 710112c9b7eba4d52570784dcd21fddab5840a92 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
|
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
XORG_EAUTORECONF=yes
inherit xorg-3 pam systemd
DEFAULTVT=vt7
DESCRIPTION="X.Org xdm application"
KEYWORDS="~alpha amd64 arm ~arm64 ~hppa ~ia64 ~mips ppc ppc64 ~s390 sparc x86"
IUSE="ipv6 pam systemd truetype xinerama xpm"
RDEPEND="
x11-apps/sessreg
x11-apps/xconsole
x11-apps/xinit
x11-apps/xrdb
x11-apps/xsm
x11-libs/libX11
x11-libs/libXaw
x11-libs/libXdmcp
x11-libs/libXmu
x11-libs/libXt
virtual/libcrypt:=
pam? ( sys-libs/pam )
systemd? ( >=sys-apps/systemd-209 )
truetype? (
x11-libs/libXrender
x11-libs/libXft
)
xinerama? ( x11-libs/libXinerama )
xpm? ( x11-libs/libXpm )
elibc_glibc? ( dev-libs/libbsd )"
DEPEND="${RDEPEND}
x11-base/xorg-proto"
src_prepare() {
local PATCHES=(
"${FILESDIR}"/${P}-consolekit.patch # bug 747124
"${FILESDIR}"/${P}-make-xinerama-optional.patch
)
sed -i -e 's:^Alias=.*$:Alias=display-manager.service:' \
xdm.service.in || die
# Disable XDM-AUTHORIZATION-1 (bug #445662).
# it causes issue with libreoffice and SDL games (bug #306223).
sed -i -e '/authorize/a DisplayManager*authName: MIT-MAGIC-COOKIE-1' \
config/xdm-config.in || die
xorg-3_src_prepare
}
src_configure() {
local XORG_CONFIGURE_OPTIONS=(
$(use_enable ipv6)
$(use_with pam)
$(use_with systemd systemd-daemon)
$(use_with truetype xft)
$(use_with xinerama)
$(use_enable xpm xpm-logos)
--with-systemdsystemunitdir="$(systemd_get_systemunitdir)"
--with-default-vt=${DEFAULTVT}
--with-xdmconfigdir=/etc/X11/xdm
)
xorg-3_src_configure
}
src_install() {
xorg-3_src_install
exeinto /usr/$(get_libdir)/X11/xdm
doexe "${FILESDIR}"/Xsession
use pam && pamd_mimic system-local-login xdm auth account session
# Keep /var/lib/xdm. This is where authfiles are stored. See #286350.
keepdir /var/lib/xdm
}
|
GitWeb