blob: e6c763fff666efcd92b8b2d82a65fcf09b81c0ab (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
|
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit flag-o-matic systemd toolchain-funcs udev
DESCRIPTION="Tool for running RAID systems - replacement for the raidtools"
HOMEPAGE="https://git.kernel.org/pub/scm/utils/mdadm/mdadm.git/"
DEB_PF="4.2~rc2-7"
SRC_URI="https://www.kernel.org/pub/linux/utils/raid/mdadm/${P/_/-}.tar.xz
mirror://debian/pool/main/m/mdadm/${PN}_${DEB_PF}.debian.tar.xz"
LICENSE="GPL-2"
SLOT="0"
[[ "${PV}" = *_rc* ]] || \
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86"
IUSE="static systemd +udev"
# Only sys-fs/eudev provides static-libs right now, so if you have systemd,
# you need to choose between static or udev, as your udev won't have static libs.
# bug #830485
REQUIRED_USE="systemd? ( ?? ( static udev ) )"
BDEPEND="app-arch/xz-utils
virtual/pkgconfig"
DEPEND="udev? (
static? ( !systemd? ( sys-fs/eudev[static-libs] ) )
!static? ( virtual/libudev:= )
)"
RDEPEND=">=sys-apps/util-linux-2.16
udev? ( !static? ( virtual/libudev:= ) )"
# The tests edit values in /proc and run tests on software raid devices.
# Thus, they shouldn't be run on systems with active software RAID devices.
RESTRICT="test"
PATCHES=(
"${FILESDIR}/${PN}"-3.4-sysmacros.patch #580188
"${FILESDIR}/${PN}"-4.2-in_initrd-collision.patch #830461
)
mdadm_emake() {
# We should probably make corosync & libdlm into USE flags. #573782
local args=(
PKG_CONFIG="$(tc-getPKG_CONFIG)"
CC="$(tc-getCC)"
CWFLAGS="-Wall"
CXFLAGS="${CFLAGS}"
UDEVDIR="$(get_udevdir)"
SYSTEMD_DIR="$(systemd_get_systemunitdir)"
COROSYNC="-DNO_COROSYNC"
DLM="-DNO_DLM"
# https://bugs.gentoo.org/732276
STRIP=
"$@"
)
emake "${args[@]}"
}
src_compile() {
use static && append-ldflags -static
# CPPFLAGS won't work for this
use udev || append-cflags -DNO_LIBUDEV
mdadm_emake all
}
src_test() {
mdadm_emake test
sh ./test || die
}
src_install() {
mdadm_emake DESTDIR="${D}" install install-systemd
dodoc ChangeLog INSTALL TODO README* ANNOUNCE-*
insinto /etc
newins mdadm.conf-example mdadm.conf
newinitd "${FILESDIR}"/mdadm.rc mdadm
newconfd "${FILESDIR}"/mdadm.confd mdadm
newinitd "${FILESDIR}"/mdraid.rc mdraid
newconfd "${FILESDIR}"/mdraid.confd mdraid
# From the Debian patchset
into /usr
dodoc "${WORKDIR}"/debian/README.checkarray
dosbin "${WORKDIR}"/debian/checkarray
insinto /etc/default
newins "${FILESDIR}"/etc-default-mdadm mdadm
exeinto /etc/cron.weekly
newexe "${FILESDIR}"/mdadm.weekly mdadm
}
pkg_postinst() {
if ! systemd_is_booted; then
if [[ -z ${REPLACING_VERSIONS} ]] ; then
# Only inform people the first time they install.
elog "If you're not relying on kernel auto-detect of your RAID"
elog "devices, you need to add 'mdraid' to your 'boot' runlevel:"
elog " rc-update add mdraid boot"
fi
fi
}
|
GitWeb