blob: dfe534db6194e2103cb425ddf4e1e188110e7d82 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
|
# Copyright 2002-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI="7"
MY_PN="${PN}-cross"
MY_P="${MY_PN}-${PV}"
inherit autotools flag-o-matic git-r3 systemd
DESCRIPTION="Modifies ELFs to avoid runtime symbol resolutions resulting in faster load times"
HOMEPAGE="https://git.yoctoproject.org/cgit/cgit.cgi/prelink-cross/ https://people.redhat.com/jakub/prelink"
EGIT_REPO_URI="https://git.yoctoproject.org/git/prelink-cross"
LICENSE="GPL-2"
SLOT="0"
IUSE="doc selinux"
RDEPEND=">=dev-libs/elfutils-0.100
selinux? ( sys-libs/libselinux )
!dev-libs/libelf"
DEPEND="${RDEPEND}
sys-libs/binutils-libs"
PATCHES=(
"${FILESDIR}"/${PN}-20130503-prelink-conf.patch
"${FILESDIR}"/${PN}-20130503-libiberty-md5.patch
)
src_prepare() {
default
sed -i -e '/^CC=/s: : -Wl,--disable-new-dtags :' testsuite/functions.sh #100147
has_version 'dev-libs/elfutils[threads]' && append-ldflags -pthread
eautoreconf
}
src_configure() {
econf $(use_enable selinux)
}
src_test() {
# prelink tests check exact library lists.
# LD_PRELOADed libraries break the assumption.
SANDBOX_ON=0 LD_PRELOAD= emake check VERBOSE=1
}
src_install() {
default
use doc && dodoc doc/prelink.pdf
insinto /etc
doins doc/prelink.conf
exeinto /etc/cron.daily
newexe "${FILESDIR}"/prelink.cron prelink
newconfd "${FILESDIR}"/prelink.confd prelink
systemd_dounit "${FILESDIR}"/prelink.{service,timer}
}
pkg_postinst() {
if [ -z "${REPLACING_VERSIONS}" ] ; then
elog "You may wish to read the Gentoo Linux Prelink Guide, which can be"
elog "found online at:"
elog " https://wiki.gentoo.org/wiki/Prelink"
elog "Please edit /etc/conf.d/prelink to enable and configure prelink"
fi
}
|
GitWeb
