blob: a7dc840c4d4311984c5229e853367753742258b9 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
|
# Copyright 1999-2018 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
EAPI="5"
LIBTOOLIZE="true" #225559
WANT_LIBTOOL="none"
inherit autotools epatch epunt-cxx multilib unpacker prefix
if [[ ${PV} == "9999" ]] ; then
EGIT_REPO_URI="git://git.savannah.gnu.org/${PN}.git
http://git.savannah.gnu.org/r/${PN}.git"
inherit git-r3
else
SRC_URI="mirror://gnu/${PN}/${P}.tar.xz"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris ~x86-winnt"
fi
DESCRIPTION="A shared library tool for developers"
HOMEPAGE="https://www.gnu.org/software/libtool/"
LICENSE="GPL-2"
SLOT="2"
IUSE="vanilla"
# Pull in libltdl directly until we convert packages to the new dep.
RDEPEND="sys-devel/gnuconfig
>=sys-devel/autoconf-2.69
>=sys-devel/automake-1.13
dev-libs/libltdl:0
!<sys-apps/sandbox-2.10-r4"
DEPEND="${RDEPEND}
app-arch/xz-utils"
[[ ${PV} == "9999" ]] && DEPEND+=" sys-apps/help2man"
src_unpack() {
if [[ ${PV} == "9999" ]] ; then
git-r3_src_unpack
cd "${S}"
./bootstrap || die
else
unpacker_src_unpack
fi
}
src_prepare() {
use vanilla && return 0
epatch "${FILESDIR}"/${PN}-2.4.3-use-linux-version-in-fbsd.patch #109105
epatch "${FILESDIR}"/${P}-link-specs.patch
epatch "${FILESDIR}"/${P}-link-fsanitize.patch #573744
epatch "${FILESDIR}"/${P}-link-fuse-ld.patch
epatch "${FILESDIR}"/${P}-libtoolize-slow.patch
epatch "${FILESDIR}"/${P}-libtoolize-delay-help.patch
epatch "${FILESDIR}"/${P}-sed-quote-speedup.patch #542252
epatch "${FILESDIR}"/${P}-ppc64le.patch #581314
epatch "${FILESDIR}"/${PN}-2.4.6-mint.patch
epatch "${FILESDIR}"/${PN}-2.2.6a-darwin-module-bundle.patch
epatch "${FILESDIR}"/${PN}-2.4.6-darwin-use-linux-version.patch
if use prefix ; then
# seems that libtool has to know about EPREFIX a little bit
# better, since it fails to find prefix paths to search libs
# from, resulting in some packages building static only, since
# libtool is fooled into thinking that libraries are unavailable
# (argh...). This could also be fixed by making the gcc wrapper
# return the correct result for -print-search-dirs (doesn't
# include prefix dirs ...).
epatch "${FILESDIR}"/${PN}-2.2.10-eprefix.patch
eprefixify m4/libtool.m4
fi
pushd libltdl >/dev/null
AT_NOELIBTOOLIZE=yes eautoreconf
popd >/dev/null
AT_NOELIBTOOLIZE=yes eautoreconf
epunt_cxx
# Make sure timestamps don't trigger a rebuild of man pages. #556512
if [[ ${PV} != "9999" ]] ; then
touch doc/*.1
export HELP2MAN=false
fi
}
src_configure() {
# the libtool script uses bash code in it and at configure time, tries
# to find a bash shell. if /bin/sh is bash, it uses that. this can
# cause problems for people who switch /bin/sh on the fly to other
# shells, so just force libtool to use /bin/bash all the time.
export CONFIG_SHELL=$(type -P bash)
# Do not bother hardcoding the full path to sed. Just rely on $PATH. #574550
export ac_cv_path_SED=$(basename "$(type -P sed)")
local myconf
[[ ${CHOST} == *-darwin* ]] && myconf="--program-prefix=g"
ECONF_SOURCE=${S} econf ${myconf} --disable-ltdl-install
}
src_test() {
emake check
}
src_install() {
default
local x
while read -d $'\0' -r x ; do
ln -sf "${EPREFIX}"/usr/share/gnuconfig/${x##*/} "${x}" || die
done < <(find "${ED}" '(' -name config.guess -o -name config.sub ')' -print0)
}
|
GitWeb