blob: 231bcb851dcf000681ed252153445a6f5888841d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
|
# Copyright 1999-2017 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
EAPI=6
inherit toolchain-funcs multilib
DESCRIPTION="GNU awk pattern-matching language"
HOMEPAGE="https://www.gnu.org/software/gawk/gawk.html"
SRC_URI="mirror://gnu/gawk/${P}.tar.xz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~x64-cygwin ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
IUSE="mpfr nls readline"
RDEPEND="
dev-libs/gmp:0=
mpfr? ( dev-libs/mpfr:0= )
readline? ( sys-libs/readline:0= )
"
DEPEND="${RDEPEND}
nls? ( sys-devel/gettext )"
src_prepare() {
default
# use symlinks rather than hardlinks, and disable version links
sed -i \
-e '/^LN =/s:=.*:= $(LN_S):' \
-e '/install-exec-hook:/s|$|\nfoo:|' \
Makefile.in doc/Makefile.in || die
sed -i '/^pty1:$/s|$|\n_pty1:|' test/Makefile.in #413327
# disable pointless build time hack that breaks cross-compiling #493362
sed -i \
-e '/check-recursive all-recursive: check-for-shared-lib-support/d' \
extension/Makefile.in || die
# fix standards conflict on Solaris
if [[ ${CHOST} == *-solaris* ]] ; then
sed -i \
-e '/\<_XOPEN_SOURCE\>/s/1$/600/' \
-e '/\<_XOPEN_SOURCE_EXTENDED\>/s/1//' \
extension/inplace.c || die
fi
}
src_configure() {
export ac_cv_libsigsegv=no
local myeconfargs=(
--libexec='$(libdir)/misc'
$(use_with mpfr)
$(use_enable nls)
$(use_with readline)
)
econf "${myeconfargs[@]}"
}
src_install() {
rm -rf README_d # automatic dodocs barfs
default
# Install headers
insinto /usr/include/awk
doins *.h || die
rm "${ED}"/usr/include/awk/config.h || die
}
pkg_postinst() {
# symlink creation here as the links do not belong to gawk, but to any awk
if has_version app-admin/eselect \
&& has_version app-eselect/eselect-awk ; then
eselect awk update ifunset
else
local l
for l in "${EROOT%/}"/usr/share/man/man1/gawk.1* "${EROOT%/}"/usr/bin/gawk; do
[[ -e ${l} && ! -e ${l/gawk/awk} ]] && ln -s "${l##*/}" "${l/gawk/awk}"
done
[[ ! -e ${EROOT%/}/bin/awk ]] && ln -s "../usr/bin/gawk" "${EROOT%/}/bin/awk"
fi
}
pkg_postrm() {
if has_version app-admin/eselect \
&& has_version app-eselect/eselect-awk ; then
eselect awk update ifunset
fi
}
|
GitWeb