blob: 20aaab87c6fa09cb62d8600e782791752c239b10 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
|
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit desktop multilib xdg
DESCRIPTION="Wolfram Mathematica"
SRC_URI="Mathematica_${PV}_LINUX.sh"
HOMEPAGE="https://www.wolfram.com/mathematica/"
LICENSE="all-rights-reserved"
KEYWORDS="-* ~amd64"
SLOT="0"
IUSE="+doc"
RESTRICT="strip mirror bindist fetch"
DEPEND=""
# Mathematica comes with a lot of bundled stuff. We should place here only what we
# explicitly override with LD_PRELOAD.
RDEPEND="
media-libs/freetype
"
# we need this a few times
MPN="Mathematica"
MPV=$(ver_cut 1-2)
M_BINARIES="MathKernel Mathematica MathematicaScript WolframKernel WolframScript math mathematica mcc wolfram"
M_TARGET="opt/Wolfram/${MPN}/${MPV}"
# we might as well list all files in all QA variables...
QA_PREBUILT="opt/*"
S=${WORKDIR}
src_unpack() {
/bin/sh "${DISTDIR}/${A}" --nox11 --keep --target "${S}/unpack" -- "-help" || die
}
src_prepare() {
default
pushd "${S}/unpack" > /dev/null || die
# fix ACCESS DENIED issue when installer check the avahi-daemon
sed -e "s:avahi-daemon -c:true:g" -i "Unix/Installer/MathInstaller" || die
/bin/sh "Unix/Installer/MathInstaller" -auto "-targetdir=${S}/${M_TARGET}" "-execdir=${S}/opt/bin" || die
popd > /dev/null || die
}
src_install() {
local ARCH='-x86-64'
if ! use doc; then
einfo "Removing documentation"
rm -r "${S}/${M_TARGET}/Documentation"
fi
einfo 'Removing MacOS- and Windows-specific files'
find AddOns SystemFiles -type d -\( -name Windows -o -name Windows-x86-64 \
-o -name MacOSX -o -name MacOSX-x86-64 -\) -delete
# move all over
mv "${S}"/opt "${D}"/opt || die
# the autogenerated symlinks point into sandbox, remove
rm "${D}"/opt/bin/* || die
# install wrappers instead
for name in ${M_BINARIES} ; do
einfo "Generating wrapper for ${name}"
echo '#!/bin/sh' >> "${T}/${name}"
echo "LD_PRELOAD=/usr/$(get_libdir)/libfreetype.so.6:/$(get_libdir)/libz.so.1 /${M_TARGET}/Executables/${name} \$*" \
>> "${T}/${name}"
dobin "${T}/${name}"
done
for name in ${M_BINARIES} ; do
einfo "Symlinking ${name} to /opt/bin"
dosym ../../usr/bin/${name} /opt/bin/${name}
done
# fix some embedded paths and install desktop files
for filename in $(find "${D}/${M_TARGET}/SystemFiles/Installation" -name "wolfram-mathematica.desktop") ; do
echo Fixing "${filename}"
sed -e "s:${S}::g" -e 's:^\t\t::g' -i "${filename}"
echo "Categories=Physics;Science;Engineering;2DGraphics;Graphics;" >> "${filename}"
domenu "${filename}"
done
# install mime types
insinto /usr/share/mime/application
for filename in $(find "${D}/${M_TARGET}/SystemFiles/Installation" -name "application-*.xml"); do
basefilename=$(basename "${filename}")
mv "${filename}" "${T}/${basefilename#application-}"
doins "${T}/${basefilename#application-}"
done
}
pkg_nofetch() {
einfo "Please place the Wolfram Mathematica installation file ${SRC_URI}"
einfo "in your \$\{DISTDIR\}."
einfo "Note that to actually run and use Mathematica you need a valid license."
einfo "Wolfram provides time-limited evaluation licenses at ${HOMEPAGE}"
}
|
GitWeb