blob: dce7bc19ece64ceb026333e45386e8e6daf5e71c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
|
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit toolchain-funcs
DESCRIPTION="Reverse-search algorithm for vertex enumeration problems"
HOMEPAGE="http://cgm.cs.mcgill.ca/~avis/C/lrs.html"
SRC_URI="http://cgm.cs.mcgill.ca/~avis/C/lrslib/archive/${P}.tar.gz"
# COPYING is GPL-2, but e.g. lrslib.h says "or ... any later version."
LICENSE="GPL-2+"
SLOT="0"
KEYWORDS="amd64 ~arm ~x86 ~amd64-linux ~x86-linux"
IUSE="gmp mpi"
BDEPEND=""
RDEPEND="
gmp? (
dev-libs/gmp:0=
mpi? ( virtual/mpi )
)"
DEPEND="${RDEPEND}"
src_prepare() {
default
tc-export CC
# The "makefile" sort-of supports CFLAGS as of lrslib-071b, but
# "-O3" is still included verbatim in many targets. Likewise, a
# LIBDIR variable exists but "lib" remains hard-coded in the install
# targets.
sed -e "s/-O3/${CFLAGS}/g" \
-e 's/$(CC) -shared/$(CC) $(LDFLAGS) -shared/' \
-e "s,/usr/local,${EPREFIX}/usr,g" \
-e "s,/lib,/$(get_libdir),g" \
-i makefile || die
}
src_compile() {
if use gmp ; then
emake
emake all-shared
use mpi && emake mplrs
else
emake allmp
fi
}
src_install() {
emake DESTDIR="${D}" prefix="${EPREFIX}/usr" install-common
if use gmp; then
emake DESTDIR="${D}" prefix="${EPREFIX}/usr" install
use mpi && dobin mplrs
fi
dodoc README
}
|
GitWeb
