blob: 9ed5ecf5c58ff594f75abcd99a0a4e7dd57f9ae4 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
|
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit cmake toolchain-funcs
DESCRIPTION="Support for parallel scientific applications"
HOMEPAGE="http://www.p4est.org/"
if [[ ${PV} == *9999 ]]; then
inherit git-r3
EGIT_REPO_URI="https://github.com/cburstedde/${PN}.git"
EGIT_BRANCH="develop"
else
SRC_URI="https://github.com/cburstedde/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
KEYWORDS="~amd64 ~x86"
fi
LICENSE="LGPL-2.1+"
SLOT="0"
IUSE="debug examples mpi openmp threads"
RDEPEND="
sys-apps/util-linux
sys-libs/zlib
virtual/blas
virtual/lapack
mpi? ( virtual/mpi[romio] )"
DEPEND="${RDEPEND}"
BDEPEND="virtual/pkgconfig"
PATCHES=(
"${FILESDIR}"/${P}-set_version.patch
"${FILESDIR}"/${P}-fix_build_system.patch
)
pkg_pretend() {
[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
}
pkg_setup() {
[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
}
src_configure() {
local mycmakeargs=(
-Dmpi="$(usex mpi)"
-Dopenmp="$(usex openmp)"
-Dlibrary_reldir="$(get_libdir)"
)
cmake_src_configure
}
src_install() {
cmake_src_install
rm -r "${ED}"/usr/include/getopt.h \
"${ED}"/usr/include/getopt_int.h \
"${ED}"/usr/include/sc_builtin || die "rm failed"
mv "${ED}"/usr/share/docs/SC/* "${ED}"/usr/share/doc/${P}/ || die "mv failed"
rm -r "${ED}"/usr/share/docs || die "rm failed"
}
|
GitWeb
