sci-libs/cqrlib/cqrlib-1.1.4.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50

# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

inherit autotools

MY_PN=CQRlib
MY_P="${MY_PN}-${PV}"

DESCRIPTION="Utility library for quaternion arithmetic / rotation math (ANSI C implemented)"
HOMEPAGE="http://cqrlib.sourceforge.net/"
SRC_URI="https://github.com/yayahjb/${PN}/archive/${MY_P}/${P}.tar.gz"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="amd64 ppc x86 ~amd64-linux ~x86-linux"
IUSE=""

RDEPEND="dev-libs/cvector"
DEPEND="${RDEPEND}"

DOCS=( README_CQRlib.txt )
HTML_DOCS=( README_CQRlib.html )

S="${WORKDIR}"/${PN}-${MY_P}

PATCHES=(
	"${FILESDIR}/${PV}-libtool.patch" # 778911
	"${FILESDIR}/${PV}-build.patch"
)

src_prepare() {
	default
	eautoreconf
}

src_compile() {
	emake all
}

src_test() {
	emake tests
}

src_install() {
	emake install DESTDIR="${D}"
	einstalldocs
	find "${D}" -name '*.la' -delete || die
}