blob: 225ebefda32707b94d6ef6014a52f162b9f4d2e0 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
|
# Copyright 1999-2019 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=6
PYTHON_COMPAT=( python2_7 python3_{5,6} )
inherit cmake-multilib eutils python-any-r1 toolchain-funcs
DESCRIPTION="Nonlinear least-squares minimizer"
HOMEPAGE="http://ceres-solver.org/"
SRC_URI="${HOMEPAGE}/${P}.tar.gz"
LICENSE="sparse? ( BSD ) !sparse? ( LGPL-2.1 ) cxsparse? ( BSD )"
SLOT="0/1"
KEYWORDS="amd64 ~x86 ~amd64-linux ~x86-linux"
IUSE="cxsparse c++11 doc examples gflags lapack openmp +schur sparse test"
RESTRICT="!test? ( test )"
REQUIRED_USE="test? ( gflags ) sparse? ( lapack ) abi_x86_32? ( !sparse !lapack )"
RDEPEND="
dev-cpp/glog[gflags?,${MULTILIB_USEDEP}]
cxsparse? ( sci-libs/cxsparse:0= )
lapack? ( virtual/lapack )
sparse? (
sci-libs/amd:0=
sci-libs/camd:0=
sci-libs/ccolamd:0=
sci-libs/cholmod:0=[metis]
sci-libs/colamd:0=
sci-libs/spqr:0=
)"
DEPEND="${RDEPEND}
dev-cpp/eigen:3
doc? ( dev-python/sphinx dev-python/sphinx_rtd_theme )
lapack? ( virtual/pkgconfig )
${PYTHON_DEPS}"
pkg_pretend() {
if [[ ${MERGE_TYPE} != binary ]] && use openmp; then
if [[ $(tc-getCXX) == *g++* ]] && ! tc-has-openmp; then
ewarn "OpenMP is not available in your current selected gcc"
die "need openmp capable gcc"
fi
fi
}
pkg_setup() {
use doc && python-any-r1_pkg_setup
}
src_prepare() {
# search paths work for prefix
sed -e "s:/usr:${EPREFIX}/usr:g" \
-i cmake/*.cmake || die
# remove Werror
sed -e 's/-Werror=(all|extra)//g' \
-i CMakeLists.txt || die
# respect gentoo doc install directory
sed -e "s:share/doc/ceres:share/doc/${PF}:" \
-i docs/source/CMakeLists.txt || die
cmake-utils_src_prepare
}
src_configure() {
# CUSTOM_BLAS=OFF EIGENSPARSE=OFF MINIGLOG=OFF CXX11=OFF
local mycmakeargs=(
-DBUILD_SHARED_LIBS=ON
-DBUILD_EXAMPLES=OFF
-DENABLE_TESTING="$(usex test)"
-DCXX11="$(usex c++11)"
-DBUILD_DOCUMENTATION="$(usex doc)"
-DGFLAGS="$(usex gflags)"
-DLAPACK="$(usex lapack)"
-DOPENMP="$(usex openmp)"
-DSCHUR_SPECIALIZATIONS="$(usex schur)"
-DCXSPARSE="$(usex cxsparse)"
-DSUITESPARSE="$(usex sparse)"
)
use sparse || use cxsparse || mycmakeargs+=( -DEIGENSPARSE=ON )
cmake-multilib_src_configure
}
src_install() {
cmake-multilib_src_install
dodoc README.md VERSION
if use examples; then
insinto /usr/share/doc/${PF}
docompress -x /usr/share/doc/${PF}/examples
doins -r examples data
fi
}
|
GitWeb