blob: caecb9b2443e66f9a98db3e1ad9283f2829e38b4 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
|
# Copyright 1999-2016 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$
EAPI=5
inherit eutils autotools systemd user
DESCRIPTION="An opensource alternative to shoutcast that supports mp3, ogg (vorbis/theora) and aac streaming"
HOMEPAGE="http://www.icecast.org/"
SRC_URI="http://downloads.xiph.org/releases/icecast/${P}.tar.gz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86 ~x86-fbsd"
IUSE="kate logrotate +speex +ssl +theora +yp"
#Although there is a --with-ogg and --with-orbis configure option, they're
#only useful for specifying paths, not for disabling.
DEPEND="dev-libs/libxslt
dev-libs/libxml2
media-libs/libogg
media-libs/libvorbis
kate? ( media-libs/libkate )
logrotate? ( app-admin/logrotate )
speex? ( media-libs/speex )
theora? ( media-libs/libtheora )
yp? ( net-misc/curl )
ssl? ( dev-libs/openssl:0= )"
RDEPEND="${DEPEND}"
pkg_setup() {
enewuser icecast -1 -1 -1 nogroup
}
src_prepare() {
# bug #368539
epatch "${FILESDIR}"/${PN}-2.3.3-libkate.patch
# bug #430434
epatch "${FILESDIR}"/${PN}-2.3.3-fix-xiph_openssl.patch
eautoreconf
}
src_configure() {
econf \
--disable-dependency-tracking \
--docdir=/usr/share/doc/${PF} \
--sysconfdir=/etc/icecast2 \
$(use_enable kate) \
$(use_with theora) \
$(use_with speex) \
$(use_with yp curl) \
$(use_with ssl openssl) \
$(use_enable yp)
}
src_install() {
emake DESTDIR="${D}" install
dodoc AUTHORS README TODO HACKING NEWS conf/icecast.xml.dist
dohtml -A chm,hhc,hhp doc/*
newinitd "${FILESDIR}"/init.d.icecast-2 icecast
systemd_dounit "${FILESDIR}"/${PN}.service
insinto /etc/icecast2
doins "${FILESDIR}"/icecast.xml
fperms 600 /etc/icecast2/icecast.xml
if use logrotate; then
dodir /etc/logrotate.d
insopts -m0644
insinto /etc/logrotate.d
newins "${FILESDIR}"/${PN}.logrotate ${PN}
fi
diropts -m0764 -o icecast -g nogroup
dodir /var/log/icecast
keepdir /var/log/icecast
rm -rf "${D}"/usr/share/doc/icecast
}
pkg_postinst() {
touch "${ROOT}"var/log/icecast/{access,error}.log
chown icecast:nogroup "${ROOT}"var/log/icecast/{access,error}.log
}
|
GitWeb