blob: bb75309c7f91d02427feb9a528b0ae4be827d25a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
|
# Copyright 1999-2016 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$
EAPI=6
inherit eutils git-r3 systemd toolchain-funcs
DESCRIPTION="NTP client and server programs"
HOMEPAGE="http://chrony.tuxfamily.org/"
EGIT_REPO_URI="git://git.tuxfamily.org/gitroot/chrony/chrony.git"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS=""
IUSE="caps +cmdmon ipv6 libedit +ntp +phc pps readline +refclock +rtc selinux +adns"
REQUIRED_USE="
?? ( libedit readline )
"
CDEPEND="
caps? ( sys-libs/libcap )
libedit? ( dev-libs/libedit )
readline? ( >=sys-libs/readline-4.1-r4:= )
"
DEPEND="
${CDEPEND}
dev-ruby/asciidoctor
pps? ( net-misc/pps-tools )
"
RDEPEND="
${CDEPEND}
selinux? ( sec-policy/selinux-chronyd )
"
RESTRICT=test
S="${WORKDIR}/${P/_/-}"
src_prepare() {
sed -i \
-e 's:/etc/chrony\.:/etc/chrony/chrony.:g' \
-e 's:/var/run:/run:g' \
conf.c doc/*.adoc examples/* || die
default
}
src_configure() {
tc-export CC
local CHRONY_EDITLINE
# ./configure legend:
# --disable-readline : disable line editing entirely
# --without-readline : do not use sys-libs/readline (enabled by default)
# --without-editline : do not use dev-libs/libedit (enabled by default)
if ! use readline && ! use libedit; then
CHRONY_EDITLINE='--disable-readline'
else
CHRONY_EDITLINE+=" $(usex readline '' --without-readline)"
CHRONY_EDITLINE+=" $(usex libedit '' --without-editline)"
fi
# not an autotools generated script
local CHRONY_CONFIGURE="
./configure \
$(usex caps '' --disable-linuxcaps) \
$(usex cmdmon '' --disable-cmdmon) \
$(usex ipv6 '' --disable-ipv6) \
$(usex ntp '' --disable-ntp) \
$(usex phc '' --disable-phc) \
$(usex pps '' --disable-pps) \
$(usex rtc '' --disable-rtc) \
$(usex refclock '' --disable-refclock) \
$(usex adns '' --disable-asyncdns) \
${CHRONY_EDITLINE} \
${EXTRA_ECONF} \
--docdir=/usr/share/doc/${PF} \
--chronysockdir=/run/chrony \
--mandir=/usr/share/man \
--prefix=/usr \
--sysconfdir=/etc/chrony \
--disable-sechash \
--without-nss \
--without-tomcrypt
"
# print the ./configure call to aid in future debugging
einfo ${CHRONY_CONFIGURE}
bash ${CHRONY_CONFIGURE} || die
}
src_compile() {
emake all docs
}
src_install() {
default
newinitd "${FILESDIR}"/chronyd.init-r1 chronyd
newconfd "${FILESDIR}"/chronyd.conf chronyd
insinto /etc/${PN}
newins examples/chrony.conf.example1 chrony.conf
docinto examples
dodoc examples/*.example*
docinto html
dodoc doc/*.html
keepdir /var/{lib,log}/chrony
insinto /etc/logrotate.d
newins "${FILESDIR}"/chrony-2.4-r1.logrotate chrony
systemd_newunit "${FILESDIR}"/chronyd.service-r2 chronyd.service
systemd_enable_ntpunit 50-chrony chronyd.service
}
|
GitWeb