blob: 69bea4fae032388acf5aa610d1701555111c49eb (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
|
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit autotools flag-o-matic toolchain-funcs
DESCRIPTION="A network programming library in C++"
HOMEPAGE="https://github.com/apenwarr/wvstreams"
SRC_URI="
mirror://debian/pool/main/w/${PN}/${PN}_${PV/_p*}.orig.tar.gz
mirror://debian/pool/main/w/${PN}/${PN}_${PV/_p/-}.debian.tar.xz
"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha amd64 hppa ppc sparc x86"
IUSE="boost +dbus debug doc libressl pam"
#Tests fail if openssl is not compiled with -DPURIFY. Gentoo's isn't. FAIL!
RESTRICT="test"
#QA Fail: xplc is compiled as a part of wvstreams.
#It'll take a larger patching effort to get it extracted, since upstream integrated it
#more tightly this time. Probably for the better since upstream xplc seems dead.
RDEPEND="
sys-libs/readline:0=
sys-libs/zlib
dbus? ( >=sys-apps/dbus-1.4.20 )
!libressl? ( >=dev-libs/openssl-1.1:0= )
libressl? ( dev-libs/libressl:0= )
pam? ( sys-libs/pam )
"
DEPEND="
${RDEPEND}
virtual/pkgconfig
doc? ( app-doc/doxygen )
boost? ( >=dev-libs/boost-1.34.1:= )
"
DOCS="ChangeLog README*"
PATCHES=(
"${FILESDIR}"/${PN}-4.6.1-autoconf.patch
"${FILESDIR}"/${PN}-4.6.1-gcc47.patch
"${FILESDIR}"/${PN}-4.6.1-parallel-make.patch
"${FILESDIR}"/${PN}-4.6.1-_DEFAULT_SOURCE.patch
)
S=${WORKDIR}/${P/_p*}
src_prepare() {
default
eapply $(awk '{ print "'"${WORKDIR}"'/debian/patches/" $0; }' < "${WORKDIR}"/debian/patches/series)
eapply "${FILESDIR}"/${P}-libressl.patch # bug 687096
eautoreconf
}
src_configure() {
append-flags -fno-strict-aliasing
append-flags -fno-tree-dce -fno-optimize-sibling-calls #421375
tc-export AR CXX
use boost && export ac_cv_header_tr1_functional=no
econf \
$(use_enable debug) \
$(use_with dbus) \
$(use_with pam) \
--cache-file="${T}"/config.cache \
--disable-optimization \
--localstatedir=/var \
--with-openssl \
--with-zlib \
--without-qt \
--without-tcl \
--without-valgrind
}
src_compile() {
default
if use doc; then
doxygen || die
fi
}
src_test() {
emake test
}
src_install() {
default
if use doc; then
docinto html
dodoc -r Docs/doxy-html/*
fi
}
|
GitWeb