blob: 77e5c5b9b408e3596b75226a2add70cccb0d3a83 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
|
# Copyright 1999-2018 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
EAPI=6
PYTHON_COMPAT=( python2_7 python3_{4,5} )
PYTHON_REQ_USE="threads"
DISTUTILS_OPTIONAL=true
DISTUTILS_IN_SOURCE_BUILD=true
inherit distutils-r1 versionator
MY_PV=$(replace_all_version_separators _)
DESCRIPTION="C++ BitTorrent implementation focusing on efficiency and scalability"
HOMEPAGE="http://libtorrent.org"
SRC_URI="https://github.com/arvidn/libtorrent/releases/download/libtorrent-${MY_PV}/${P}.tar.gz"
LICENSE="BSD"
SLOT="0/8"
KEYWORDS="amd64 arm ppc ppc64 ~sparc x86 ~x86-fbsd"
IUSE="debug +dht doc examples +geoip libressl python +ssl static-libs test"
REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
COMMON_DEPEND="
dev-libs/boost:=[threads]
virtual/libiconv
geoip? ( dev-libs/geoip )
python? (
${PYTHON_DEPS}
dev-libs/boost:=[python,${PYTHON_USEDEP}]
)
ssl? (
!libressl? ( dev-libs/openssl:0= )
libressl? ( dev-libs/libressl:= )
)
"
DEPEND="${COMMON_DEPEND}
sys-devel/libtool
"
RDEPEND="${COMMON_DEPEND}
examples? ( !net-p2p/mldonkey )
"
PATCHES=(
"${FILESDIR}/${PN}-1.0.9-test_torrent_parse.patch"
# RC_1_0 branch
"${FILESDIR}/${P}-fix-abicompat.patch"
"${FILESDIR}/${P}-move-header.patch"
# master branch
"${FILESDIR}/${P}-fix-test_ssl.patch"
"${FILESDIR}/${P}-boost-config-header.patch"
)
src_prepare() {
default
# bug 578026
# prepend -L${S}/... to ensure bindings link against the lib we just built
sed -i -e "s|^|-L${S}/src/.libs |" bindings/python/compile_flags.in || die
use python && distutils-r1_src_prepare
}
src_configure() {
local myeconfargs=(
$(use_enable debug)
$(use_enable debug logging)
$(use_enable debug statistics)
$(use_enable debug disk-stats)
$(use_enable dht dht $(usex debug logging yes))
$(use_enable examples)
$(use_enable geoip)
$(use_with geoip libgeoip)
$(use_enable ssl encryption)
$(use_enable static-libs static)
$(use_enable test tests)
--with-libiconv
)
econf "${myeconfargs[@]}"
if use python; then
myeconfargs+=(
--enable-python-binding
--with-boost-python
)
python_configure() {
econf "${myeconfargs[@]}"
}
distutils-r1_src_configure
fi
}
src_compile() {
default
python_compile() {
cd "${BUILD_DIR}/../bindings/python" || die
distutils-r1_python_compile
}
use python && distutils-r1_src_compile
}
src_install() {
use doc && HTML_DOCS+=( "${S}"/docs )
default
python_install() {
cd "${BUILD_DIR}/../bindings/python" || die
distutils-r1_python_install
}
use python && distutils-r1_src_install
find "${D}" -name '*.la' -delete || die
}
|
GitWeb