blob: 7714599a617d312a0752d6d74a2cbaf68f90d188 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
|
# Copyright 1999-2016 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
EAPI=6
DESCRIPTION="A framework for managing DNS information"
HOMEPAGE="http://roy.marples.name/projects/openresolv"
SRC_URI="http://roy.marples.name/downloads/${PN}/${P}.tar.xz"
LICENSE="BSD-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~sparc-fbsd ~x86-fbsd"
IUSE="selinux"
DEPEND="!net-dns/resolvconf-gentoo
!<net-dns/dnsmasq-2.40-r1"
RDEPEND="selinux? ( sec-policy/selinux-resolvconf )"
PATCHES=(
"${FILESDIR}/3.8.1-restore-newline.patch"
)
src_configure() {
econf \
--prefix="${EPREFIX}" \
--rundir="${EPREFIX}"/var/run \
--libexecdir="${EPREFIX}"/lib/resolvconf
}
pkg_config() {
if [[ ${ROOT} != / ]]; then
eerror "We cannot configure unless \$ROOT=/"
return 1
fi
if [[ -n "$(resolvconf -l)" ]]; then
einfo "${PN} already has DNS information"
else
ebegin "Copying /etc/resolv.conf to resolvconf -a dummy"
resolvconf -a dummy </etc/resolv.conf
eend $? || return $?
einfo "The dummy interface will disappear when you next reboot"
fi
}
|
GitWeb
