blob: 42b6aeb30b0478717bc589373a7d8c20538c491c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
|
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit autotools bash-completion-r1 fcaps
DESCRIPTION="My TraceRoute, an Excellent network diagnostic tool"
HOMEPAGE="https://www.bitwizard.nl/mtr/"
if [[ ${PV} == *9999* ]] ; then
EGIT_REPO_URI="https://github.com/traviscross/mtr"
inherit git-r3
else
SRC_URI="https://github.com/traviscross/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos"
fi
LICENSE="GPL-2"
SLOT="0"
IUSE="gtk +ipinfo +ipv6 jansson ncurses"
# TODO: This is an inherited RESTRICT - figure out why!
RESTRICT="test"
RDEPEND="
gtk? (
dev-libs/glib:2
x11-libs/gtk+:3
)
jansson? ( dev-libs/jansson:= )
ncurses? ( sys-libs/ncurses:0= )
"
DEPEND="${RDEPEND}"
BDEPEND="virtual/pkgconfig"
DOCS=( AUTHORS FORMATS NEWS README.md SECURITY TODO )
FILECAPS=( cap_net_raw usr/sbin/mtr-packet )
PATCHES=(
"${FILESDIR}"/${PN}-0.88-tinfo.patch
)
src_prepare() {
default
eautoreconf
}
src_configure() {
econf \
$(use_enable ipv6) \
$(use_with gtk) \
$(use_with ipinfo) \
$(use_with jansson) \
$(use_with ncurses) \
--with-bashcompletiondir="$(get_bashcompdir)"
}
pkg_postinst() {
fcaps_pkg_postinst
if use prefix && [[ ${CHOST} == *-darwin* ]] ; then
ewarn "mtr needs root privileges to run. To grant them:"
ewarn " % sudo chown root ${EPREFIX}/usr/sbin/mtr"
ewarn " % sudo chmod u+s ${EPREFIX}/usr/sbin/mtr"
fi
}
|
GitWeb
