blob: 1b5132feec440ec1e7771e7c8df69bc2246980b8 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
|
# Copyright 2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit autotools toolchain-funcs
DESCRIPTION="Mark commercial breaks in VDR recordings"
HOMEPAGE="https://github.com/madmartin/noad"
SRC_URI="https://github.com/madmartin/noad/archive/v${PV}.tar.gz -> ${P}.tar.gz"
LICENSE="GPL-2+"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="+ffmpeg imagemagick libmpeg2"
BDEPEND="virtual/pkgconfig"
DEPEND="
libmpeg2? ( media-libs/libmpeg2:= )
ffmpeg? ( media-video/ffmpeg )
imagemagick? ( media-gfx/imagemagick )"
RDEPEND="${DEPEND}"
REQUIRED_USE="|| ( ffmpeg libmpeg2 )"
src_prepare() {
default
eautoreconf
}
src_configure() {
econf \
$(usex imagemagick '--with-magick') \
$(usex ffmpeg '' '--without-ffmpeg') \
$(usex libmpeg2 '' '--without-libmpeg2') \
--with-tools
}
src_install() {
dobin noad showindex checkMarks
use imagemagick && dobin markpics
dodoc README* INSTALL
# example scripts are installed as dokumentation
dodoc allnewnoad allnoad allnoadnice allnoaduncut checkAllMarks clearlogos noadcall.sh noadifnew stat2html statupd
newconfd "${FILESDIR}"/confd_vdraddon.noad vdraddon.noad
insinto /usr/share/vdr/record
doins "${FILESDIR}"/record-50-noad.sh
insinto /usr/share/vdr/shutdown
doins "${FILESDIR}"/pre-shutdown-15-noad.sh
insinto /etc/vdr/reccmds
doins "${FILESDIR}"/reccmds.noad.conf
exeinto /usr/share/vdr/bin
doexe "${FILESDIR}"/noad-reccmd
}
pkg_postinst() {
elog
elog "To integrate noad in VDR you should do this:"
elog
elog "start and set Parameter in /etc/conf.d/vdraddon.noad"
elog
elog "Note: You can use here all parameters for noad,"
elog "please look in the documentation of noad."
}
|
GitWeb
