blob: a00c18ffe048cc37716ce4b9803b605dc79783ff (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
|
# Copyright 2018-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
CMAKE_ECLASS=cmake
inherit cmake-multilib toolchain-funcs
DESCRIPTION="Video stabilization library"
HOMEPAGE="http://public.hronopik.de/vid.stab/"
if [[ ${PV} == *9999 ]] ; then
EGIT_REPO_URI="https://github.com/georgmartius/vid.stab.git"
inherit git-r3
else
SRC_URI="https://github.com/georgmartius/vid.stab/archive/v${PV}.tar.gz -> ${P}.tar.gz"
KEYWORDS="~alpha amd64 arm arm64 ~ia64 ppc ppc64 ~sparc x86"
S="${WORKDIR}/vid.stab-${PV}"
fi
LICENSE="GPL-2+"
SLOT="0"
IUSE="openmp cpu_flags_x86_sse2"
PATCHES=(
"${FILESDIR}/vidstab-1.1.0-tests-should-exit-with-code-0-on-success.patch"
"${FILESDIR}/vidstab-1.1.0-tests-use-sse2-only-if-available.patch"
"${FILESDIR}/vidstab-1.1.0-tests-1.1.0-fix-test_motiondetect-without-openmp.patch"
)
src_prepare() {
# USE=cpu_flags_x86_sse2 instead
sed -E 's#include (FindSSE)##' -i CMakeLists.txt || die
sed -E 's#include (FindSSE)##' -i tests/CMakeLists.txt || die
# strip some CFLAGS
for FILE_TO_PATCH in {,transcode/,tests/}CMakeLists.txt; do
sed -E 's#(add_definitions.* )-g #\1#' -i ${FILE_TO_PATCH} || die
sed -E 's#(add_definitions.* )-O3 #\1#' -i ${FILE_TO_PATCH} || die
done
cmake_src_prepare
}
src_configure() {
use openmp && tc-check-openmp
local mycmakeargs=(
-DUSE_OMP="$(usex openmp)"
-DSSE2_FOUND="$(usex cpu_flags_x86_sse2)"
)
cmake-multilib_src_configure
}
multilib_src_test() {
local mycmakeargs=(
-DUSE_OMP="$(usex openmp)"
-DSSE2_FOUND="$(usex cpu_flags_x86_sse2)"
)
local CMAKE_USE_DIR="${CMAKE_USE_DIR}/tests"
local BUILD_DIR="${BUILD_DIR}/tests"
cmake_src_configure
cmake_build
"${BUILD_DIR}"/tests || die
}
|
GitWeb
