blob: 95ea458a1e5d5ee7be03612638c07aeab7961a26 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
|
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
PYTHON_COMPAT=( python3_6 pypy3 )
inherit python-any-r1 multilib-minimal
MY_P=${P/_pre/pre}
DESCRIPTION="C library for reading and writing files containing sampled sound"
HOMEPAGE="http://www.mega-nerd.com/libsndfile"
if [[ ${MY_P} == ${P} ]]; then
SRC_URI="http://www.mega-nerd.com/libsndfile/files/${P}.tar.gz"
else
SRC_URI="http://www.mega-nerd.com/tmp/${MY_P}b.tar.gz"
fi
LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~mips ppc ppc64 s390 sparc x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
IUSE="alsa minimal sqlite static-libs test"
RESTRICT="!test? ( test )"
RDEPEND="
!minimal? (
>=media-libs/flac-1.2.1-r5[${MULTILIB_USEDEP}]
>=media-libs/libogg-1.3.0[${MULTILIB_USEDEP}]
>=media-libs/libvorbis-1.3.3-r1[${MULTILIB_USEDEP}]
)
alsa? ( media-libs/alsa-lib )
sqlite? ( >=dev-db/sqlite-3.2 )"
DEPEND="${RDEPEND}"
BDEPEND="
virtual/pkgconfig
test? ( ${PYTHON_DEPS} )"
S=${WORKDIR}/${MY_P}
PATCHES=(
"${FILESDIR}"/${P}-arm-varargs-failure.patch
"${FILESDIR}"/${P}-CVE-2017-12562.patch
"${FILESDIR}"/${P}-CVE-2018-13139.patch
"${FILESDIR}"/${P}-CVE-2017-6892.patch
"${FILESDIR}"/${P}-CVE-2017-836{3,5,2}.patch
"${FILESDIR}"/${P}-CVE-2017-14634.patch
)
pkg_setup() {
use test && python-any-r1_pkg_setup
}
multilib_src_configure() {
ECONF_SOURCE="${S}" econf \
--disable-octave \
--enable-gcc-pipe \
--enable-gcc-opt \
$(use_enable static-libs static) \
$(use_enable !minimal external-libs) \
$(multilib_native_enable full-suite) \
$(multilib_native_use_enable alsa) \
$(multilib_native_use_enable sqlite)
}
multilib_src_install_all() {
einstalldocs
# package provides .pc files
find "${D}" -name '*.la' -delete || die
}
|
GitWeb
