blob: 0b960e2096822c10f72af1f17bc4e7dc57b5f535 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
|
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
PYTHON_COMPAT=( python3_{6,7,8,9} )
inherit cmake flag-o-matic python-single-r1
DESCRIPTION="Library for the efficient manipulation of volumetric data"
HOMEPAGE="https://www.openvdb.org"
SRC_URI="https://github.com/AcademySoftwareFoundation/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz
https://dev.gentoo.org/~dracwyrm/patches/${P}-patchset-02.tar.xz"
LICENSE="MPL-2.0"
SLOT="0"
KEYWORDS="amd64 ~x86"
IUSE="abi3-compat abi4-compat doc python test"
RESTRICT="!test? ( test )"
REQUIRED_USE="
python? ( ${PYTHON_REQUIRED_USE} )
^^ ( abi3-compat abi4-compat )
"
RDEPEND="
dev-libs/boost:=
dev-libs/c-blosc:=
dev-libs/jemalloc:=
dev-libs/log4cplus:=
media-libs/glfw
media-libs/openexr:=
sys-libs/zlib:=
x11-libs/libXcursor
x11-libs/libXi
x11-libs/libXinerama
x11-libs/libXrandr
python? (
${PYTHON_DEPS}
$(python_gen_cond_dep '
dev-libs/boost:=[python?,${PYTHON_MULTI_USEDEP}]
dev-python/numpy[${PYTHON_MULTI_USEDEP}]
')
)"
DEPEND="${RDEPEND}
dev-cpp/tbb
virtual/pkgconfig
doc? (
app-doc/doxygen
dev-texlive/texlive-bibtexextra
dev-texlive/texlive-fontsextra
dev-texlive/texlive-fontutils
dev-texlive/texlive-latex
dev-texlive/texlive-latexextra
)
test? ( dev-util/cppunit )"
PATCHES=(
"${WORKDIR}/${P}-patchset-02/0001-use-gnuinstalldirs.patch"
"${WORKDIR}/${P}-patchset-02/0002-use-pkgconfig-for-ilmbase-and-openexr.patch"
"${WORKDIR}/${P}-patchset-02/0003-boost-1.65-numpy-support.patch"
"${FILESDIR}/${P}-findboost-fix.patch"
"${FILESDIR}/${P}-fix-const-correctness-for-unittest.patch"
"${FILESDIR}/${P}-fix-build-docs.patch"
)
pkg_setup() {
use python && python-single-r1_pkg_setup
}
src_configure() {
local myprefix="${EPREFIX}/usr/"
# To stay in sync with Boost
append-cxxflags -std=c++14
local version
if use abi3-compat; then
version=3
elif use abi4-compat; then
version=4
else
die "Openvdb abi version is not compatible"
fi
local mycmakeargs=(
-DBLOSC_LOCATION="${myprefix}"
-DCMAKE_INSTALL_DOCDIR="share/doc/${PF}"
-DGLFW3_LOCATION="${myprefix}"
-DOPENVDB_BUILD_DOCS=$(usex doc)
-DOPENVDB_BUILD_PYTHON_MODULE=$(usex python)
-DOPENVDB_BUILD_UNITTESTS=$(usex test)
-DOPENVDB_ENABLE_3_ABI_COMPATIBLE=$(usex abi3-compat)
-DOPENVDB_ENABLE_RPATH=OFF
-DTBB_LOCATION="${myprefix}"
-DUSE_GLFW3=ON
)
use python && mycmakeargs+=( -DPYOPENVDB_INSTALL_DIRECTORY="$(python_get_sitedir)" )
use test && mycmakeargs+=( -DCPPUNIT_LOCATION="${myprefix}" )
cmake_src_configure
}
|
GitWeb