blob: 0102090380d2aec7479851f73fdd43928f9aa5f3 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
|
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
PLUGIN_PKG="${PN}-plugins-$(ver_cut 1-2)"
inherit cmake xdg-utils
DESCRIPTION="Qt-based image viewer"
HOMEPAGE="https://nomacs.org/"
SRC_URI="https://github.com/${PN}/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz
plugins? ( https://github.com/${PN}/${PN}-plugins/archive/$(ver_cut 1-2).tar.gz -> ${PLUGIN_PKG}.tar.gz )"
LICENSE="GPL-3+"
SLOT="0"
KEYWORDS="amd64 ~arm64 ~riscv x86 ~amd64-linux"
IUSE="+jpeg +opencv plugins raw +tiff zip"
REQUIRED_USE="
raw? ( opencv )
tiff? ( opencv )
"
RDEPEND="
dev-qt/qtconcurrent:5
dev-qt/qtcore:5
dev-qt/qtgui:5[jpeg?]
dev-qt/qtnetwork:5
dev-qt/qtprintsupport:5
dev-qt/qtsvg:5
dev-qt/qtwidgets:5
media-gfx/exiv2:=
opencv? ( >=media-libs/opencv-3.4:= )
raw? ( media-libs/libraw:= )
tiff? (
dev-qt/qtimageformats:5
media-libs/tiff
)
zip? ( dev-libs/quazip:0= )
"
DEPEND="${RDEPEND}"
BDEPEND="
dev-qt/linguist-tools:5
virtual/pkgconfig
"
S="${WORKDIR}/${P}/ImageLounge"
DOCS=( src/changelog.txt )
PATCHES=(
"${FILESDIR}"/${P}-quazip1.patch
"${FILESDIR}"/${P}-DkMath-ostream.patch
)
src_prepare() {
if use plugins ; then
rmdir plugins || die
mv -v ../../${PLUGIN_PKG} plugins || die
# Fix nomacs-plugins installation and search library directory
sed -e "s:lib/nomacs-plugins:$(get_libdir)/nomacs-plugins:" \
-i plugins/cmake/Utils.cmake || die
sed -e "s:lib/nomacs-plugins:$(get_libdir)/nomacs-plugins:" \
-i src/DkCore/DkPluginManager.cpp || die
fi
cmake_src_prepare
}
src_configure() {
local mycmakeargs=(
-DENABLE_CODE_COV=OFF
-DUSE_SYSTEM_QUAZIP=ON
-DENABLE_TRANSLATIONS=ON
-DENABLE_OPENCV=$(usex opencv)
-DENABLE_PLUGINS=$(usex plugins)
-DENABLE_RAW=$(usex raw)
-DENABLE_TIFF=$(usex tiff)
-DENABLE_QUAZIP=$(usex zip)
)
cmake_src_configure
}
pkg_postinst() {
xdg_desktop_database_update
}
pkg_postrm() {
xdg_desktop_database_update
}
|
GitWeb