blob: 0dc933045ffdd80bee7321f53cba88f5a1a221bf (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
|
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
ECM_QTHELP="false"
ECM_TEST="forceoptional"
PVCUT=$(ver_cut 1-2)
QTMIN=5.15.2
inherit ecm kde.org optfeature xdg-utils
DESCRIPTION="Library for providing abstractions to get the developer's purposes fulfilled"
LICENSE="LGPL-2.1+"
KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
IUSE="bluetooth +kaccounts"
# requires running environment
RESTRICT+=" test"
DEPEND="
>=dev-qt/qtdeclarative-${QTMIN}:5
>=dev-qt/qtgui-${QTMIN}:5
>=dev-qt/qtnetwork-${QTMIN}:5
>=dev-qt/qtwidgets-${QTMIN}:5
=kde-frameworks/kcoreaddons-${PVCUT}*:5
=kde-frameworks/ki18n-${PVCUT}*:5
=kde-frameworks/kio-${PVCUT}*:5
=kde-frameworks/kirigami-${PVCUT}*:5
=kde-frameworks/knotifications-${PVCUT}*:5
kaccounts? (
>=kde-apps/kaccounts-integration-19.04.3:5
net-libs/accounts-qt
)
"
RDEPEND="${DEPEND}
>=dev-qt/qtquickcontrols-${QTMIN}:5
>=dev-qt/qtquickcontrols2-${QTMIN}:5
>=kde-frameworks/kdeclarative-${PVCUT}:5
bluetooth? ( =kde-frameworks/bluez-qt-${PVCUT}*:5 )
kaccounts? ( net-libs/accounts-qml )
"
src_prepare() {
ecm_src_prepare
use bluetooth ||
cmake_run_in src/plugins cmake_comment_add_subdirectory bluetooth
}
src_configure() {
local mycmakeargs=(
$(cmake_use_find_package kaccounts KAccounts)
)
ecm_src_configure
}
pkg_postinst() {
if [[ -z "${REPLACING_VERSIONS}" ]]; then
optfeature "Send through KDE Connect" kde-misc/kdeconnect
fi
ecm_pkg_postinst
xdg_icon_cache_update
}
pkg_postrm() {
xdg_icon_cache_update
}
|
GitWeb
