blob: a105c5722610b27ee9d18d4868ea1e2f1455d3ef (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
|
# Copyright 2020-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
PYTHON_COMPAT=( python3_{7..9} )
inherit meson python-any-r1
DESCRIPTION="Transparent network proxy for Wayland compositors"
HOMEPAGE="https://gitlab.freedesktop.org/mstoeckl/waypipe"
if [[ ${PV} == 9999 ]]; then
inherit git-r3
EGIT_REPO_URI="https://gitlab.freedesktop.org/mstoeckl/waypipe"
else
SRC_URI="https://gitlab.freedesktop.org/mstoeckl/waypipe/-/archive/v${PV}/${PN}-v${PV}.tar.gz -> ${P}.tar.gz"
S="${WORKDIR}"/${PN}-v${PV}
KEYWORDS="~amd64 ~arm ~arm64 ~x86"
fi
LICENSE="MIT"
SLOT="0"
WAYPIPE_FLAG_MAP_X86=( avx2:with_avx2 avx512f:with_avx512f sse3:with_sse3 )
WAYPIPE_FLAG_MAP_ARM=( neon:with_neon_opts )
WAYPIPE_FLAG_MAP=(
"${WAYPIPE_FLAG_MAP_X86[@]/#/cpu_flags_x86_}"
"${WAYPIPE_FLAG_MAP_ARM[@]/#/cpu_flags_arm_}"
)
IUSE="dmabuf ffmpeg lz4 man neon systemtap test vaapi zstd ${WAYPIPE_FLAG_MAP[@]%:*}"
REQUIRED_USE="vaapi? ( ffmpeg )"
RESTRICT="!test? ( test )"
DEPEND="
dmabuf? (
media-libs/mesa[gbm,vaapi?,wayland]
x11-libs/libdrm
)
lz4? ( app-arch/lz4 )
systemtap? ( dev-util/systemtap )
vaapi? ( x11-libs/libva[drm,wayland] )
ffmpeg? (
media-video/ffmpeg[x264,vaapi?]
)
zstd? ( app-arch/zstd )
"
RDEPEND="${DEPEND}"
BDEPEND="
${PYTHON_DEPS}
virtual/pkgconfig
man? ( app-text/scdoc )
test? ( dev-libs/weston[examples,headless,remoting,screen-sharing,wayland-compositor] )
"
src_configure() {
local emesonargs=(
-Dwerror=false
$(meson_use systemtap with_systemtap)
$(meson_feature dmabuf with_dmabuf)
$(meson_feature ffmpeg with_video)
$(meson_feature lz4 with_lz4)
$(meson_feature man man-pages)
$(meson_feature vaapi with_vaapi)
$(meson_feature zstd with_zstd)
)
local fl
for fl in "${WAYPIPE_FLAG_MAP[@]}"; do
emesonargs+=( $(meson_use "${fl%:*}" "${fl#*:}") )
done
meson_src_configure
}
|
GitWeb
