blob: 346e749e13c04d0f974ba1f7f171a70eccec2062 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
|
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=( python3_{8..10} )
VALA_MIN_API_VERSION="0.40"
inherit gnome.org gnome2-utils meson python-any-r1 vala virtualx xdg
DESCRIPTION="A calculator application for GNOME"
HOMEPAGE="https://wiki.gnome.org/Apps/Calculator"
LICENSE="GPL-3+"
SLOT="0"
IUSE="+introspection test"
KEYWORDS="~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~riscv ~sparc"
# gtksourceview vapi definitions in dev-lang/vala itself are too old, and newer vala removes them
# altogether, thus we need them installed by gtksourceview[vala]
RDEPEND="
>=dev-libs/glib-2.40.0:2
dev-libs/libxml2:2
>=net-libs/libsoup-2.42:2.4
>=dev-libs/libgee-0.20.0:0.8
dev-libs/mpc:=
dev-libs/mpfr:0=
>=gui-libs/gtk-4.4.1:4
>=gui-libs/libadwaita-1.0.0:1
>=gui-libs/gtksourceview-5.3.0:5
introspection? ( >=dev-libs/gobject-introspection-1.58:= )
"
DEPEND="${RDEPEND}"
BDEPEND="
${PYTHON_DEPS}
dev-libs/appstream-glib
dev-util/itstool
>=sys-devel/gettext-0.19.8
virtual/pkgconfig
$(vala_depend)
net-libs/libsoup:2.4[vala]
gui-libs/gtksourceview:5[vala]
gui-libs/libhandy:1[vala]
"
src_prepare() {
default
vala_setup
# Automagic dep on valadoc - don't bother for now
sed -e '/subdir.*doc/d' -i meson.build || die
}
src_configure() {
local emesonargs=(
-Ddisable-ui=false
#-Dvala-version # doesn't do anything in 3.34
$(meson_use !introspection disable-introspection)
$(meson_use test ui-tests)
)
meson_src_configure
}
src_test() {
virtx meson_src_test
}
pkg_postinst() {
xdg_pkg_postinst
gnome2_schemas_update
}
pkg_postrm() {
xdg_pkg_postrm
gnome2_schemas_update
}
|
GitWeb
