blob: b15834855402bae9879b58769f4014337203917d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
|
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
LUA_COMPAT=( lua5-1 luajit )
PYTHON_COMPAT=( python3_{10..13} )
inherit lua-single meson python-any-r1 virtualx xdg
DESCRIPTION="2D space trading and combat game, in a similar vein to Escape Velocity"
HOMEPAGE="https://naev.org/"
SRC_URI="https://github.com/naev/naev/releases/download/v${PV}/${P}-source.tar.xz"
LICENSE="
GPL-3+
Apache-2.0 BSD BSD-2 CC-BY-2.0 CC-BY-3.0 CC-BY-4.0 CC-BY-SA-3.0
CC-BY-SA-4.0 CC0-1.0 GPL-2+ MIT OFL-1.1 public-domain
"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="doc"
REQUIRED_USE="${LUA_REQUIRED_USE}"
# dlopen: libglvnd
RDEPEND="
${LUA_DEPS}
dev-games/physfs
dev-libs/libpcre2:=
dev-libs/libunibreak:=
dev-libs/libxml2
media-libs/freetype:2
media-libs/libglvnd
media-libs/libsdl2[joystick,opengl,video]
media-libs/libvorbis
media-libs/openal
media-libs/sdl2-image[png,webp]
net-libs/enet:1.3=
sci-libs/cholmod
sci-libs/cxsparse
sci-libs/openblas
sci-libs/suitesparse
sci-mathematics/glpk:=
virtual/libintl
"
DEPEND="
${RDEPEND}
test? (
dev-games/physfs[zip]
media-libs/libsdl2[X]
)
"
BDEPEND="
$(python_gen_any_dep 'dev-python/pyyaml[${PYTHON_USEDEP}]')
sys-devel/gettext
doc? (
app-text/doxygen
dev-lua/ldoc
media-gfx/graphviz
)
test? (
media-libs/mesa[llvm]
x11-base/xorg-server[-minimal]
)
"
python_check_deps() {
python_has_version "dev-python/pyyaml[${PYTHON_USEDEP}]"
}
pkg_setup() {
lua-single_pkg_setup
python-any-r1_pkg_setup
}
src_prepare() {
default
# use eclass' generated lua.pc first rather than as fallback
sed -i "s/'lua51'/'lua'/" meson.build || die
# don't probe OpenGL for tests (avoids sandbox violations, bug #829369),
# mesa[llvm] should ensure software rendering will work
sed -i "/subdir('glcheck')/d" test/meson.build || die
}
src_configure() {
local emesonargs=(
$(meson_feature doc docs_c)
$(meson_feature doc docs_lua)
$(meson_feature lua_single_target_luajit luajit)
)
meson_src_configure
}
src_test() {
virtx meson_src_test
}
src_install() {
local DOCS=( CHANGELOG Readme.md )
meson_src_install
if use doc; then
dodir /usr/share/doc/${PF}/html
mv -- "${ED}"/usr/{doc/naev/{c,lua},share/doc/${PF}/html} || die
rm -r -- "${ED}"/usr/doc || die
fi
rm -r -- "${ED}"/usr/share/doc/naev || die
}
|
GitWeb