blob: a2fb0f2ce9488292495a175b741771e52eee93a9 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
|
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
LUA_COMPAT=( lua5-{3..4} )
inherit cmake lua-single xdg
if [[ ${PV} == 9999 ]] ; then
inherit git-r3
EGIT_REPO_URI="https://github.com/mgba-emu/mgba.git"
else
SRC_URI="https://github.com/mgba-emu/mgba/archive/${PV}.tar.gz -> ${P}.tar.gz"
KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
fi
DESCRIPTION="Game Boy Advance Emulator"
HOMEPAGE="https://mgba.io/"
LICENSE="MPL-2.0 BSD LGPL-2.1+ public-domain discord? ( MIT )"
SLOT="0/$(ver_cut 1-2)"
IUSE="debug discord elf ffmpeg gles2 gles3 gui libretro lua +opengl +sdl +sqlite test"
REQUIRED_USE="
gui? ( || ( gles2 gles3 opengl ) sqlite )
lua? ( ${LUA_REQUIRED_USE} )"
RESTRICT="!test? ( test )"
RDEPEND="
media-libs/libpng:=
sys-libs/zlib:=[minizip]
debug? ( dev-libs/libedit )
elf? ( dev-libs/elfutils )
ffmpeg? ( media-video/ffmpeg:= )
gles2? ( media-libs/libglvnd )
gles3? ( media-libs/libglvnd )
lua? ( ${LUA_DEPS} )
opengl? ( media-libs/libglvnd )
gui? (
dev-qt/qtcore:5
dev-qt/qtgui:5
dev-qt/qtmultimedia:5
dev-qt/qtnetwork:5
dev-qt/qtwidgets:5
)
sdl? ( media-libs/libsdl2[sound,joystick,gles2?,opengl?,video] )
sqlite? ( dev-db/sqlite:3 )"
DEPEND="
${RDEPEND}
test? ( dev-util/cmocka )"
BDEPEND="lua? ( virtual/pkgconfig )"
PATCHES=(
"${FILESDIR}"/${PN}-0.10.0-optional-updater.patch
)
pkg_setup() {
use lua && lua-single_pkg_setup
}
src_configure() {
local mycmakeargs=(
-DBUILD_CINEMA=$(usex test)
-DBUILD_GL=$(usex opengl)
-DBUILD_GLES2=$(usex gles2)
-DBUILD_GLES3=$(usex gles3)
-DBUILD_LIBRETRO=$(usex libretro)
-DBUILD_QT=$(usex gui)
-DBUILD_SDL=$(usex sdl) # also used for gamepads in QT build
-DBUILD_SUITE=$(usex test)
-DBUILD_UPDATER=OFF
-DENABLE_SCRIPTING=$(usex lua)
-DMARKDOWN=OFF #752048
-DUSE_DEBUGGERS=$(usex debug)
-DUSE_DISCORD_RPC=$(usex discord)
-DUSE_EDITLINE=$(usex debug)
-DUSE_ELF=$(usex elf)
-DUSE_EPOXY=OFF
-DUSE_FFMPEG=$(usex ffmpeg)
-DUSE_GDB_STUB=$(usex debug)
-DUSE_LIBZIP=OFF
-DUSE_LZMA=ON
-DUSE_MINIZIP=ON
-DUSE_PNG=ON
-DUSE_SQLITE3=$(usex sqlite)
-DUSE_ZLIB=ON
$(usev libretro -DLIBRETRO_LIBDIR="${EPREFIX}"/usr/$(get_libdir)/libretro)
)
use lua && mycmakeargs+=( -DUSE_LUA=$(ver_cut 1-2 $(lua_get_version)) )
cmake_src_configure
}
src_test() {
# CMakeLists.txt forces SKIP_RPATH=ON when PREFIX=/usr
local -x LD_LIBRARY_PATH=${BUILD_DIR}:${LD_LIBRARY_PATH}
cmake_src_test
}
src_install() {
cmake_src_install
use !test || rm "${ED}"/usr/bin/mgba-cinema || die
rm -r "${ED}"/usr/share/doc/${PF}/{LICENSE,licenses} || die
}
|
GitWeb