dev-vcs/git-num/git-num-2.0.1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36

# Copyright 1999-2017 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2

EAPI=5
USE_RUBY="ruby22 ruby23 ruby24"

RUBY_FAKEGEM_RECIPE_DOC="rdoc"
RUBY_FAKEGEM_EXTRADOC="README.md CHANGELOG.md"
RUBY_FAKEGEM_RECIPE_TEST="rspec3"

inherit ruby-fakegem

DESCRIPTION="Quickly reference files in Git using numbers"
HOMEPAGE="https://github.com/schreifels/git-num"
SRC_URI="https://github.com/schreifels/git-num/archive/v${PV}.tar.gz -> ${P}.tar.gz"

LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64"
IUSE="test"

DEPEND+=" test? ( dev-vcs/git )"
RDEPEND+=" dev-vcs/git"

all_ruby_prepare() {
	# cp git-num since specs depend on the default location
	mkdir bin || die
	cp git-num bin || die

	sed -i -e '14i`git config user.email "test-git-num@gentoo.org"`' \
		-e '15i`git config user.name "git-num tester"`' spec/lib/git_tools.rb || die
}

each_ruby_test() {
	RSPEC_VERSION=3 ruby-ng_rspec spec/unit.rb spec/integration.rb
}