blob: e236b9aeee0ed9d43aa02b26d3341a9d92c97b41 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
|
# Copyright 2021-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=( python3_{8..11} )
inherit distutils-r1
DESCRIPTION="Command-line processors for YAML/JSON/Compatible data"
HOMEPAGE="https://github.com/wwkimball/yamlpath https://github.com/wwkimball/yamlpath/wiki"
SRC_URI="
https://github.com/wwkimball/yamlpath/archive/v${PV}.tar.gz
-> ${P}.gh.tar.gz
"
LICENSE="ISC"
SLOT="0"
KEYWORDS="~amd64"
RDEPEND="
dev-python/ruamel-yaml[${PYTHON_USEDEP}]
"
BDEPEND="
test? (
dev-python/pytest-console-scripts[${PYTHON_USEDEP}]
dev-ruby/hiera-eyaml
)
"
distutils_enable_tests --install pytest
python_prepare_all() {
sed -e '/ruamel\.yaml/d' \
-e '/pytest-cov/d' \
-e "/find_packages/s/()/(exclude=\['tests'\])/" \
-i setup.py || die
distutils-r1_python_prepare_all
}
python_install() {
distutils-r1_python_install
# install and optimize yamlpath/patches/aliasstyle.py
local sitedir=$(python_get_sitedir)
[[ -d ${D}${sitedir} ]] || die "${D}${sitedir}: No such directory"
insinto "${sitedir}/yamlpath"
doins -r "${S}/yamlpath/patches"
python_optimize "${D}${sitedir}"
}
|
GitWeb
