dev-python/pyicu/pyicu-2.0.3.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48

# Copyright 1999-2018 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2

EAPI=7

PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6} )

inherit distutils-r1 flag-o-matic

MY_PN="PyICU"
MY_P="${MY_PN}-${PV}"

DESCRIPTION="Python bindings for dev-libs/icu"
HOMEPAGE="https://github.com/ovalhub/pyicu"
SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"

LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="test"

RDEPEND="${PYTHON_DEPS}
	dev-libs/icu"
DEPEND="${RDEPEND}
	test? ( dev-python/pytest
		dev-python/six )"
REQUIRED_USE="${PYTHON_REQUIRED_USE}"

S="${WORKDIR}/${MY_P}"

DOCS=(CHANGES CREDITS README.md)

python_prepare_all() {
	# bug 651748
	# due to ICU 59 requiring C++11 now
	append-cxxflags -std=c++11

	distutils-r1_python_prepare_all
}

python_test() {
	if [[ ${EPYTHON} == python2* ]]; then
		# See Bug #644226
		ewarn "Skipping tests for ${EPYTHON} because they are known to fail"
	else
		esetup.py test
	fi
}