dev-python/pulsectl-asyncio/pulsectl-asyncio-1.1.1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41

# Copyright 2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

DISTUTILS_USE_PEP517=setuptools
PYTHON_COMPAT=( python3_{10..12} )

inherit distutils-r1

DESCRIPTION="Asyncio frontend for pulsectl, Python bindings of libpulse"
HOMEPAGE="
	https://github.com/mhthies/pulsectl-asyncio/
	https://pypi.org/project/pulsectl-asyncio/
"
# sdist is missing examples that are used in tests
SRC_URI="
	https://github.com/mhthies/pulsectl-asyncio/archive/v${PV}.tar.gz
		-> ${P}.gh.tar.gz
"

LICENSE="MIT"
SLOT="0"
KEYWORDS="amd64 ~riscv ~x86"

RDEPEND="
	>=dev-python/pulsectl-23.5.0[${PYTHON_USEDEP}]
"
BDEPEND="
	test? (
		media-sound/pulseaudio-daemon
	)
"

distutils_enable_tests pytest

src_prepare() {
	# unpin deps
	sed -i -e 's:,<=[0-9.]*::' setup.cfg || die
	distutils-r1_src_prepare
}