blob: 618acc93c1662ee24ef5a95e8ccb829839f1d3a0 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_USE_PEP517=setuptools
PYTHON_COMPAT=( python3_{10..12} )
inherit distutils-r1
MY_P=hcloud-python-${PV}
DESCRIPTION="Official Hetzner Cloud python library"
HOMEPAGE="
https://github.com/hetznercloud/hcloud-python/
https://pypi.org/project/hcloud/
"
# sdist is missing doc assets as of 1.19.0
# https://github.com/hetznercloud/hcloud-python/pull/183
SRC_URI="
https://github.com/hetznercloud/hcloud-python/archive/v${PV}.tar.gz
-> ${MY_P}.gh.tar.gz
"
S=${WORKDIR}/${MY_P}
LICENSE="MIT"
SLOT="0"
KEYWORDS="amd64"
IUSE="examples"
RDEPEND="
>=dev-python/python-dateutil-2.7.5[${PYTHON_USEDEP}]
>=dev-python/requests-2.20[${PYTHON_USEDEP}]
"
distutils_enable_sphinx docs \
dev-python/myst-parser \
dev-python/sphinx-rtd-theme
distutils_enable_tests pytest
EPYTEST_IGNORE=(
# Integration tests need docker:
# https://github.com/hetznercloud/hcloud-python/blob/master/.travis.yml#L16
tests/integration
)
python_install_all() {
use examples && dodoc -r examples
distutils-r1_python_install_all
}
|
GitWeb
