blob: 8a82aba57b913641d74a33f4b705056ceb207082 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
|
# Copyright 1999-2018 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
EAPI=6
DIST_AUTHOR=MIKEM
DIST_VERSION=1.82
DIST_EXAMPLES=("examples/*")
inherit multilib perl-module
DESCRIPTION="Perl extension for using OpenSSL"
LICENSE="openssl"
SLOT="0"
KEYWORDS="alpha amd64 arm arm64 hppa ia64 ~m68k ~mips ppc ppc64 s390 ~sh sparc x86 ~ppc-aix ~x64-cygwin ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
IUSE="libressl test minimal examples"
RDEPEND="
!libressl? ( dev-libs/openssl:0= )
libressl? ( dev-libs/libressl:0= )
virtual/perl-MIME-Base64
"
DEPEND="${RDEPEND}
virtual/perl-ExtUtils-MakeMaker
test? (
!minimal? (
dev-perl/Test-Exception
dev-perl/Test-Warn
dev-perl/Test-NoWarnings
)
virtual/perl-Test-Simple
)
"
export OPTIMIZE="$CFLAGS"
export OPENSSL_PREFIX=${EPREFIX}/usr
PATCHES=(
"${FILESDIR}/${PN}-1.82-respect-cflags.patch"
"${FILESDIR}/${PN}-1.82-fix-libdir.patch"
"${FILESDIR}/${PN}-1.82-fix-network-tests.patch"
)
src_prepare() {
use test && perl_rm_files 't/local/01_pod.t' 't/local/02_pod_coverage.t' 't/local/kwalitee.t'
perl-module_src_prepare
}
src_configure() {
if use test && has network ${DIST_TEST_OVERRIDE:-${DIST_TEST:-do parallel}}; then
export NETWORK_TESTS=yes
else
use test && einfo "Network tests will be skipped without DIST_TEST_OVERRIDE=~network"
export NETWORK_TESTS=no
fi
export LIBDIR=$(get_libdir)
perl-module_src_configure
}
|
GitWeb
