blob: 7d8204ffd001c9b17fa10c99eb38c36f36e9b3b6 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
|
# Copyright 1999-2018 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=6
inherit eutils cmake-utils
DESCRIPTION="i3-compatible Wayland window manager"
HOMEPAGE="http://swaywm.org/"
SRC_URI="https://github.com/swaywm/sway/archive/${PV}.tar.gz -> ${P}.tar.gz"
LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~arm64 ~x86"
IUSE="+gdk-pixbuf +swaybar +swaybg swaygrab swaylock +swaymsg systemd +tray wallpapers zsh-completion"
REQUIRED_USE="tray? ( swaybar )"
RDEPEND=">=dev-libs/wlc-0.0.8[systemd=]
dev-libs/json-c:0=
dev-libs/libpcre
dev-libs/libinput
dev-libs/wayland
sys-libs/libcap
x11-libs/libxkbcommon
x11-libs/cairo
x11-libs/pango
gdk-pixbuf? ( x11-libs/gdk-pixbuf[jpeg] )
swaylock? ( virtual/pam )
tray? ( sys-apps/dbus )"
DEPEND="${RDEPEND}
app-text/asciidoc
virtual/pkgconfig"
src_prepare() {
cmake-utils_src_prepare
# remove bad CFLAGS that upstream is trying to add
sed -i -e '/add_compile_options/s/-Werror//' CMakeLists.txt || die
}
src_configure() {
local mycmakeargs=(
-Denable-swaybar=$(usex swaybar)
-Denable-swaybg=$(usex swaybg)
-Denable-swaygrab=$(usex swaygrab)
-Denable-swaylock=$(usex swaylock)
-Denable-swaymsg=$(usex swaymsg)
-Denable-tray=$(usex tray)
-Ddefault-wallpaper=$(usex wallpapers)
-Denable-gdk-pixbuf=$(usex gdk-pixbuf)
-Dzsh-completions=$(usex zsh-completion)
-DCMAKE_INSTALL_SYSCONFDIR="/etc"
-DVERSION="${PV}"
)
cmake-utils_src_configure
}
src_install() {
cmake-utils_src_install
use !systemd && fperms u+s /usr/bin/sway
}
pkg_postinst() {
if use swaygrab
then
optfeature "swaygrab screenshot support" media-gfx/imagemagick[png]
optfeature "swaygrab video capture support" virtual/ffmpeg
fi
if use tray
then
optfeature "experimental xembed tray icons support" kde-plasma/xembed-sni-proxy
fi
optfeature "X11 applications support" dev-libs/wlc[xwayland] x11-base/xorg-server[wayland]
}
|
GitWeb