blob: ede9a159d9533e397a92119e9f123d85f1096416 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
|
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI="7"
inherit multilib toolchain-funcs
DESCRIPTION="A Library for Large Linear Classification"
HOMEPAGE="https://www.csie.ntu.edu.tw/~cjlin/liblinear/ https://github.com/cjlin1/liblinear"
SRC_URI="https://github.com/cjlin1/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
LICENSE="BSD"
SLOT="0/4"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86 ~x64-macos"
src_prepare() {
default
sed -i \
-e '/^AR/s|=|?=|g' \
-e '/^RANLIB/s|=|?=|g' \
-e '/^CFLAGS/d;/^CXXFLAGS/d' \
blas/Makefile || die
sed -i \
-e 's|make|$(MAKE)|g' \
-e '/$(LIBS)/s|$(CFLAGS)|& $(LDFLAGS)|g' \
-e '/^CFLAGS/d;/^CXXFLAGS/d' \
-e 's|$${SHARED_LIB_FLAG}|& $(LDFLAGS)|g' \
Makefile || die
}
src_compile() {
emake \
CC="$(tc-getCC)" \
CXX="$(tc-getCXX)" \
CFLAGS="${CFLAGS} -fPIC" \
CXXFLAGS="${CXXFLAGS} -fPIC" \
AR="$(tc-getAR) rcv" \
RANLIB="$(tc-getRANLIB)" \
lib all
}
src_install() {
dolib.so ${PN}.so.4
dosym ${PN}.so.4 /usr/$(get_libdir)/${PN}.so
newbin predict ${PN}-predict
newbin train ${PN}-train
doheader linear.h
dodoc README
}
|
GitWeb
