blob: 7d8dbfd7e5f3ccc8a6b6ffe1be22f3d57e931356 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
|
# Copyright 1999-2019 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
PYTHON_COMPAT=( python3_{5,6,7} )
VALA_USE_DEPEND="vapigen"
inherit cmake-utils python-any-r1 vala
DESCRIPTION="An implementation of basic iCAL protocols"
HOMEPAGE="https://github.com/libical/libical"
SRC_URI="https://github.com/${PN}/${PN}/releases/download/v${PV}/${P}.tar.gz"
LICENSE="|| ( MPL-2.0 LGPL-2.1 )"
SLOT="0/3"
KEYWORDS="alpha amd64 arm arm64 ~hppa ia64 ~mips ppc ppc64 sparc x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos ~x86-solaris"
IUSE="berkdb doc examples introspection static-libs test vala"
RESTRICT="!test? ( test )"
REQUIRED_USE="vala? ( introspection )"
BDEPEND="
dev-lang/perl
virtual/pkgconfig
doc? ( app-doc/doxygen )
introspection? ( dev-libs/gobject-introspection )
test? ( ${PYTHON_DEPS} )
vala? ( $(vala_depend) )
"
COMMON_DEPEND="
dev-libs/icu:=
berkdb? ( sys-libs/db:= )
introspection? ( dev-libs/glib:2 )
"
DEPEND="${COMMON_DEPEND}
introspection? ( dev-libs/libxml2:2 )
"
RDEPEND="${COMMON_DEPEND}
sys-libs/timezone-data
"
DOCS=(
AUTHORS ReadMe.txt ReleaseNotes.txt TEST THANKS TODO
doc/{AddingOrModifyingComponents,UsingLibical}.txt
)
PATCHES=(
"${FILESDIR}/${PN}-3.0.4-tests.patch"
"${FILESDIR}/${PN}-3.0.5-pkgconfig-libdir.patch"
)
pkg_setup() {
use test && python-any-r1_pkg_setup
}
src_prepare() {
cmake-utils_src_prepare
use examples || cmake_comment_add_subdirectory examples
use vala && vala_src_prepare
}
src_configure() {
local mycmakeargs=(
$(cmake-utils_use_find_package berkdb BDB)
-DICAL_BUILD_DOCS=$(usex doc)
-DICAL_GLIB=$(usex introspection)
-DGOBJECT_INTROSPECTION=$(usex introspection)
-DSHARED_ONLY=$(usex !static-libs)
-DLIBICAL_BUILD_TESTING=$(usex test)
-DICAL_GLIB_VAPI=$(usex vala)
)
if use vala; then
mycmakeargs+=(
-DVALAC="${VALAC}"
-DVAPIGEN="${VAPIGEN}"
)
fi
cmake-utils_src_configure
}
src_compile() {
cmake-utils_src_compile
use doc && cmake-utils_src_compile docs
}
src_test() {
local myctestargs=(
-E "(icalrecurtest|icalrecurtest-r)" # bug 660282
)
cmake-utils_src_test
}
src_install() {
use doc && HTML_DOCS=( "${BUILD_DIR}"/apidocs/html/. )
cmake-utils_src_install
if use examples; then
rm examples/CMakeLists.txt || die
dodoc -r examples
fi
}
|
GitWeb