blob: 2a3ed8af6ae2d81deed9ee9932376a2a1f2a0567 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
|
# Copyright 1999-2017 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
EAPI=6
PYTHON_COMPAT=( python{3_4,3_5,3_6} )
VALA_USE_DEPEND="vapigen"
inherit gnome2 python-r1 vala
DESCRIPTION="Git library for GLib"
HOMEPAGE="https://wiki.gnome.org/Projects/Libgit2-glib"
LICENSE="LGPL-2+"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="python +ssh +vala"
REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
# Specify libgit2 dependency with subslot because libgit2 upstream has a habit
# of changing their API in each release in ways that break libgit2-glib
RDEPEND="
>=dev-libs/gobject-introspection-0.10.1:=
>=dev-libs/glib-2.44.0:2
>=dev-libs/libgit2-0.26.0:0/26[ssh?]
python? (
${PYTHON_DEPS}
dev-python/pygobject:3[${PYTHON_USEDEP}] )
"
DEPEND="${RDEPEND}
>=dev-util/gtk-doc-am-1.11
virtual/pkgconfig
vala? ( $(vala_depend) )
"
src_prepare() {
use vala && vala_src_prepare
gnome2_src_prepare
}
src_configure() {
gnome2_src_configure \
$(use_enable python) \
$(use_enable ssh) \
$(use_enable vala)
}
src_install() {
gnome2_src_install
if use python ; then
install_gi_override() {
python_moduleinto "$(python_get_sitedir)/gi/overrides"
python_domodule "${S}"/${PN}/Ggit.py
}
python_foreach_impl install_gi_override
fi
}
|
GitWeb
