blob: a3ee8b14b97960bcd1f19752233267fa6667b013 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
|
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=6
inherit autotools flag-o-matic linux-info pam
DESCRIPTION="Tools and libraries to configure and manage kernel control groups"
HOMEPAGE="http://libcg.sourceforge.net/"
SRC_URI="mirror://sourceforge/project/libcg/${PN}/v${PV}/${P}.tar.bz2"
LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="amd64 arm arm64 ~ppc ~ppc64 x86"
IUSE="+daemon elibc_musl pam static-libs test +tools"
RESTRICT="!test? ( test )"
RDEPEND="pam? ( sys-libs/pam )"
DEPEND="
${RDEPEND}
sys-devel/bison
sys-devel/flex
elibc_musl? ( sys-libs/fts-standalone )
"
REQUIRED_USE="daemon? ( tools )"
DOCS=(README_daemon README README_systemd INSTALL)
pkg_setup() {
local CONFIG_CHECK="~CGROUPS"
if use daemon; then
CONFIG_CHECK="${CONFIG_CHECK} ~CONNECTOR ~PROC_EVENTS"
fi
linux-info_pkg_setup
}
PATCHES=(
"${FILESDIR}"/${P}-replace_DECLS.patch
"${FILESDIR}"/${P}-replace_INLCUDES.patch
"${FILESDIR}"/${P}-reorder-headers.patch
"${FILESDIR}"/${P}-remove-umask.patch
)
src_prepare() {
default
# Change rules file location
sed -e 's:/etc/cgrules.conf:/etc/cgroup/cgrules.conf:' \
-i src/libcgroup-internal.h || die "sed failed"
sed -e 's:/etc/cgconfig.conf:/etc/cgroup/cgconfig.conf:' \
-i src/libcgroup-internal.h || die "sed failed"
sed -e 's:\(pam_cgroup_la_LDFLAGS.*\):\1\ -avoid-version:' \
-i src/pam/Makefile.am || die "sed failed"
sed -e 's#/var/run#/run#g' -i configure.in || die "sed failed"
# If we're not running tests, don't bother building them.
if ! use test; then
sed -i '/^SUBDIRS/s:tests::' Makefile.am || die
fi
eautoreconf
}
src_configure() {
local my_conf
if use pam; then
my_conf=" --enable-pam-module-dir=$(getpam_mod_dir) "
fi
use elibc_musl && append-ldflags "-lfts"
econf \
$(use_enable static-libs static) \
$(use_enable daemon) \
$(use_enable pam) \
$(use_enable tools) \
${my_conf}
}
src_test() {
# Use mount cgroup to build directory
# sandbox restricted to trivial build,
# possible kill Diego tanderbox ;)
true
}
src_install() {
default
find "${ED}" -name '*.la' -delete || die
insinto /etc/cgroup
doins samples/*.conf
if use tools; then
newconfd "${FILESDIR}"/cgconfig.confd-r1 cgconfig
newinitd "${FILESDIR}"/cgconfig.initd-r1 cgconfig
fi
if use daemon; then
newconfd "${FILESDIR}"/cgred.confd-r2 cgred
newinitd "${FILESDIR}"/cgred.initd-r1 cgred
fi
}
|
GitWeb