blob: 8b9abe61a64b4ddebc582e6aaf6b5a4208e50b84 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
|
# Copyright 1999-2019 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=6
inherit gnome2 pax-utils virtualx
DESCRIPTION="Javascript bindings for GNOME"
HOMEPAGE="https://wiki.gnome.org/Projects/Gjs"
LICENSE="MIT || ( MPL-1.1 LGPL-2+ GPL-2+ )"
SLOT="0"
IUSE="+cairo examples gtk test"
RESTRICT="!test? ( test )"
KEYWORDS="alpha amd64 arm ia64 ppc ppc64 sparc x86"
RDEPEND="
>=dev-libs/glib-2.52.1
>=dev-libs/gobject-introspection-1.52.1:=
sys-libs/readline:0=
dev-lang/spidermonkey:38
virtual/libffi:=
cairo? ( x11-libs/cairo[X] )
gtk? ( >=x11-libs/gtk+-3.20:3 )
"
DEPEND="${RDEPEND}
gnome-base/gnome-common
sys-devel/gettext
virtual/pkgconfig
test? ( sys-apps/dbus )
"
#PATCHES=(
# Disable unittest failing without pt_BR locale, upstream bug #????
# "${FILESDIR}"/1.48.6-disable-unittest.patch
#)
src_configure() {
# FIXME: add systemtap/dtrace support, like in glib:2
# FIXME: --enable-systemtap installs files in ${D}/${D} for some reason
# XXX: Do NOT enable coverage, completely useless for portage installs
gnome2_src_configure \
--disable-systemtap \
--disable-dtrace \
--disable-code-coverage \
$(use_with cairo cairo) \
$(use_with gtk) \
$(use_with test dbus-tests) \
$(use_with test xvfb-tests)
}
src_install() {
# installation sometimes fails in parallel, bug #???
gnome2_src_install -j1
if use examples; then
insinto /usr/share/doc/"${PF}"/examples
doins "${S}"/examples/*
fi
# Required for gjs-console to run correctly on PaX systems
pax-mark mr "${ED}/usr/bin/gjs-console"
}
|
GitWeb
