dev-libs/9libs/9libs-1.0-r4.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59

# Copyright 1999-2019 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7
inherit autotools toolchain-funcs

DESCRIPTION="A package of Plan 9 compatibility libraries"
HOMEPAGE="https://www.netlib.org/research/9libs/9libs-1.0.README"
SRC_URI="https://www.netlib.org/research/9libs/${P}.tar.bz2"

LICENSE="PLAN9"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="static-libs X"

DEPEND="
	X? (
		>=x11-libs/libX11-1.0.0[static-libs?]
		>=x11-libs/libXt-1.0.0[static-libs?]
	)
"
RDEPEND="
	${DEPEND}
"
DOCS=(
	README
)
PATCHES=(
	"${FILESDIR}"/${PN}-va_list.patch # Bug 385387
)

src_prepare() {
	default
	eautoreconf
}

src_configure() {
	tc-export CC

	econf \
		$(use_enable static-libs static) \
		$(use_with X x) \
		--enable-shared \
		--includedir=/usr/include/9libs
}

src_install() {
	default

	# rename some man pages to avoid collisions with dev-libs/libevent
	local f
	for f in add balloc bitblt cachechars event frame graphics rgbpix; do
		mv "${D}"/usr/share/man/man3/${f}.{3,3g} || die
	done

	if ! use static-libs; then
		find "${ED}" -name '*.la' -delete || die
	fi
}